在列中非空单元格旁边的列中显示图片

Question

I'd like to show a pic loaded from network location next to each non empty cell in range A1:A10 and name the picture after the value in that range.

Sub testpics()
Dim Cell As Range
For Each Cell In Range("A1:A10").Cells
    If Not IsEmpty(Cell) Then
        On Error GoTo ErrNoPhoto

        pictureloc = "location here" & Cell & ".jpg"

        With Cell.Offset(0, 1)
            Set mypict = ActiveSheet.Pictures.Insert(pictureloc)
                mypict.Height = .RowHeight
                mypict.Left = .Left
                mypict.Top = .Top
                mypict.Placement = xlMoveAndSize
                mypict.Name = Cell
                mypict.OnAction = "enlarge"
        End With
        Exit Sub
ErrNoPhoto:
        MsgBox "Unable to Find Photo for " & Cell
    End If
Next Cell

End Sub

So far I came up with the code above, but it only shows the pic behind A1 if I run it. What am I doing wrong/missing in my code?

Answer 1

The main issue is that you exit the loop after the first iteration. However, I refactored your code below to make it more stable, readable and better actual error trapping.

Option Explicit

Sub testpics()

    Dim Cell As Range
    For Each Cell In Range("A1:A10").Cells

        If Not IsEmpty(Cell) Then

            Dim pictureLoc As String
            pictureLoc = "location here" & Cell & ".jpg"

            Dim mypict As Object
            On Error Resume Next
            Set mypict = ActiveSheet.Pictures.Insert(pictureLoc)
            On Error GoTo 0

            If Not mypict Is Nothing Then

                With Cell.Offset(0, 1)

                    mypict.Height = .RowHeight
                    mypict.Left = .Left
                    mypict.Top = .Top
                    mypict.Placement = xlMoveAndSize
                    mypict.Name = Cell.Value
                    mypict.OnAction = "enlarge"

                End With

            Else

                Cell.Offset(0, 1).Value = "Could Not Find Pic"

            End If

        End If

    Next

End Sub