如何将基于行的上一个和下一个记录数据插入到 MS Access 时间序列数据中？

Question

In MS Access, My Table is like this:

ProductName , Date , Time , Price
Apple , 05-April-2020, 9:15:59 , 110
Apple , 05-April-2020, 9:16:59 , 112
Apple , 05-April-2020, 9:17:59 , 108
Apple , 05-April-2020, 9:18:59 , 125
Apple , 05-April-2020, 9:20:59 , 110

Apple , 06-April-2020, 10:20:59 , 85
Apple , 06-April-2020, 10:21:59 , 82
Apple , 06-April-2020, 10:22:59 , 86
Apple , 06-April-2020, 10:25:59 , 84

Orange , 05-April-2020, 2:15:59 PM , 110
Orange , 05-April-2020, 2:16:59 PM , 112
Orange , 05-April-2020, 2:17:59 PM , 108
Orange , 05-April-2020, 2:18:59 PM , 125
Orange , 05-April-2020, 2:20:59 PM , 110

Orange , 10-April-2020, 2:21:59 , 85
Orange , 10-April-2020, 2:22:59 , 82
Orange , 10-April-2020, 2:26:59 , 86
Orange , 10-April-2020, 2:27:59 , 84

The data is from 9:15:59 AM to 3:29:59 PM for each date (always 59th second) for each product (thousands) for 4 years data. I need to fill up the gaps for each product for every date, eg

9:19 AM for apple on 05 April-2020
10:23 AM for apple on 05 April-2020
10:24 AM for apple on 05 April-2020

so on. Insert new records wherever needed copying the previous record price, coresponding productName and date, and new time. If it can be (9:15 + 9:17 price)/2, for 9:16 even better. Only wherever its missing. Each Day for a specific product, if it has existence on that day, should have 375 rows coresponding to the 375 minutes from 9:15 to 3:30. Ideally there should be no more than 5-10 inserts required per product per day. If we can generate a report, we can track how many inserts were made to track any false entries.

Thanks a lot, Looking forward:)

Answer 1

I've put together some code that generates the missing records, including carrying over the last value from the previous day if needed.

However, I'm making absolutely no guarantees about the speed!!

Sub sMissingPrice()
    On Error GoTo E_Handle
    Dim db As DAO.Database
    Dim rsDay As DAO.Recordset
    Dim rsLookup As DAO.Recordset
    Dim dtmTemp As Date
    Dim strSQL As String
    Const JetDateFmt = "\#mm\/dd\/yyyy\#;;;\N\u\l\l"
    Const JetTimeFmt = "\#hh\:nn\:ss\#;;;\N\u\l\l"
    Set db = DBEngine(0)(0)
    Set rsDay = db.OpenRecordset("SELECT DISTINCT ProductName, ProductDate FROM tblProductPrice ORDER BY ProductName, ProductDate;")
    If Not (rsDay.BOF And rsDay.EOF) Then
        Do
            dtmTemp = #9:15:59 AM#
'   make sure that there is a value for 09:15:59. otherwise get the last price from the previous day
            strSQL = "SELECT ProductTime, Price FROM tblProductPrice " _
                & " WHERE ProductName='" & rsDay!ProductName & "' AND ProductDate=" & Format(rsDay!ProductDate, JetDateFmt) & " AND ProductTime=" & Format(dtmTemp, JetTimeFmt)
            Set rsLookup = db.OpenRecordset(strSQL)
            If (rsLookup.BOF And rsLookup.EOF) Then
                Set rsLookup = db.OpenRecordset("SELECT Price FROM tblProductPrice " _
                    & " WHERE ProductName='" & rsDay!ProductName & "' AND ProductDate=" & Format(rsDay!ProductDate - 1, JetDateFmt) & " AND ProductTime=" & Format(#3:29:59 PM#, JetTimeFmt))
                If Not (rsLookup.BOF And rsLookup.EOF) Then
                    db.Execute "INSERT INTO tblProductPrice (ProductName,ProductDate,ProductTime,Price) " _
                        & " SELECT '" & rsDay!ProductName & "'," & Format(rsDay!ProductDate, JetDateFmt) & "," & Format(dtmTemp, JetTimeFmt) & "," & rsLookup!Price
                End If
            End If
' now loop through each minute of the day checking to see if we have data
            Do
                strSQL = "SELECT Price FROM tblProductPrice " _
                    & " WHERE ProductName='" & rsDay!ProductName & "' AND ProductDate=" & Format(rsDay!ProductDate, JetDateFmt) & " AND ProductTime=" & Format(dtmTemp, JetTimeFmt)
                Set rsLookup = db.OpenRecordset(strSQL)
                If (rsLookup.BOF And rsLookup.EOF) Then
                    Set rsLookup = db.OpenRecordset("SELECT Price FROM tblProductPrice " _
                        & " WHERE ProductName='" & rsDay!ProductName & "' AND ProductDate=" & Format(rsDay!ProductDate, JetDateFmt) & " AND ProductTime=" & Format(DateAdd("n", -1, dtmTemp), JetTimeFmt))
                    If Not (rsLookup.BOF And rsLookup.EOF) Then
                        db.Execute "INSERT INTO tblProductPrice (ProductName, ProductDate, ProductTime, Price) " _
                            & " SELECT '" & rsDay!ProductName & "'," & Format(rsDay!ProductDate, JetDateFmt) & "," & Format(dtmTemp, JetTimeFmt) & "," & rsLookup!Price
                    End If
                End If
                dtmTemp = DateAdd("n", 1, dtmTemp)
            Loop Until dtmTemp > #3:30:00 PM#
            rsDay.MoveNext
        Loop Until rsDay.EOF
    End If
sExit:
    On Error Resume Next
    rsDay.Close
    rsLookup.Close
    Set rsDay = Nothing
    Set rsLookup = Nothing
    Set db = Nothing
    Exit Sub
E_Handle:
    MsgBox Err.Description & vbCrLf & vbCrLf & "sMissingPrice", vbOKOnly + vbCritical, "Error: " & Err.Number
    Resume sExit
End Sub

Regards,