window 表单进入无响应阶段

Question

I am new to progress 4GL. In my program, I tried to create a form using progress 4GL. The form has two fields one is DB name and another one is DB Description. The scope of this form is by default this should have one DB name and description and if a user-entered or keep blank in the field of DB name then an alert box should give a message. I have developed the form but when I run it the program keeps continuously running and window form goes not responding stage. I don't get a chance to enter or keep blank to the DB field name. Let me share my code and please help to find out what is the issue and why it's continuously running.

define variable cArcDB      as character   no-undo format "x(20)" INIT "qadb".
define variable cArcDBDesc  as character   no-undo format "x(25)" INIT "archive database".
define variable cTmp  as character   NO-UNDO.

form
cArcDB     colon 25
cArcDBDesc colon 25
with frame frArchiveDB width 80 side-labels.

MAIN-LOOP:
REPEAT:

display
     cArcDB
     cArcDBDesc
  with frame frArchiveDB.

  set
     cArcDB
  with frame frArchiveDB editing:
     if frame-field = "cArcDB" then do:
        /* Find next/prev record from ttAppDB */
        cTmp = cArcDB:input-value in frame frArchiveDB.

           display
              cArcDB
              cArcDBDesc
           with frame frArchiveDB.
        end.
  end. /* editing */
  cArcDB = trim(cArcDB).

  if cArcDB = "" then do:
     /* Blank not allowed */
   /*  {us/bbi/pxmsg.i &MSGNUM=40 &ERRORLEVEL=3} */
     next-prompt cArcDB with frame frArchiveDB.
     undo MAIN-LOOP,retry MAIN-LOOP.
  end.
  END.

Answer 1

Please have look at the online reference of the "EDITING phrase". To me it looks like you're missing the READKEY after the beginning of the EDITING block and you also need to "APPLY LASTKEY" at some point. See the sample there:

/* Update Customer fields, monitoring each keystroke during the UPDATE */
UPDATE Customer.Name Customer.Address Customer.City Customer.State SKIP
  Customer.SalesRep HELP "Use the space bar to select a SalesRep" 
  WITH 2 COLUMNS EDITING:  /* Read a keystroke */
  READKEY.
  /* If the cursor is in any field except SalesRep, execute the last key
     pressed and go on to the next iteration of this EDITING phrase to check
     the next key */
  IF FRAME-FIELD <> "SalesRep" THEN DO:
    APPLY LASTKEY.
    IF GO-PENDING THEN LEAVE.
    ELSE NEXT.
  END.
  /* When in the SalesRep field, if the last key pressed was the space bar
     then cycle through the sales reps */
  IF LASTKEY = KEYCODE(" ") THEN DO:
    FIND NEXT SalesRep NO-ERROR.
    IF NOT AVAILABLE SalesRep THEN FIND FIRST SalesRep.
    DISPLAY SalesRep.SalesRep @ Customer.SalesRep.
    NEXT.
  END.
  /* If the user presses any one of a set of keys while in the SalesRep field,
     immediately execute that key */
  IF LOOKUP(KEYFUNCTION(LASTKEY), 
    "TAB,BACK-TAB,GO,RETURN,END-ERROR") > 0 THEN APPLY LASTKEY.
  ELSE BELL.
END.