将字符串转换为元组 Haskell

Question

I'm trying to create a function for a board game that will read a position on the board as a string and convert to a coordinate that can be used in the program eg "D4 => (3,3), "F2" => (5,1)" .

So far I have this:

getCoord :: String -> Maybe(Int, Int)
getCoord s = 
    let alphas = "ABCDEFGH"
        coord1 = head(s)
        coord2 = tail(s)
    in ((elemIndex coord1 alphas)-1, read(head coord2)-1)

I'm still learning about the use of Maybe in Haskell and am encountering the error:

• Couldn't match expected type ‘Maybe (Int, Int)’
              with actual type ‘(Maybe Int, Integer)’
• In the expression:
    ((elemIndex coord1 alphas) - 1, read (head coord2) - 1)

Would appreciate your help on where I might be going wrong. Thanks!

Answer 1

The problem you're facing is that elemIndex returns a Maybe Int . Since you're also trying to return a Maybe type, the best way to work with this is using a do block to perform operations inside the Maybe monad. This lets you use Maybe values as if they were normal values as long as your output will get wrapped back up in a Maybe . (If you need more information about how monads work, there are plenty of good answers here explaining it, and lots of other great posts across the internet.)

import Text.Read (readMaybe)
import Data.List (elemIndex)

getCoords :: String -> Maybe(Int, Int)
getCoords (coord1:coord2) = do
  let alphas = "ABCDEFGH"
  row <- elemIndex coord1 alphas
  col <- readMaybe coord2
  return (row, col - 1)
getCoords _ = Nothing

Note a couple other differences from your original.

1. The use of readMaybe instead of read . readMaybe is a special version of read that returns a value of type Maybe a . Since we're already working in a Maybe context, it's better to have a no-parse return Nothing than throw an error.

2. No - 1 on the row. elemIndex already has the behavior you want, ie A will return 0 , etc.

3. Pattern match instead of head and tail . This lets you account for the case where the string is empty.

4. Extra definition to match empty list and return Nothing . The advantage of using a Maybe type is that you can return a value for errors instead of getting a Runtime error. In order to make use of that, we have to make sure we handle all of the cases.