SQL中的主从查询

Question

I am having trouble querying my data where the expected result is a master-detail type output.

I have a table. In this table I have three columns, they are all strings:

Version

URL

Application

In this table, I have the following data:

**Version**   **URL**                           **Application**
New           http://www.stackoverflow1.com     Application1
New           http://www.stackoverflow2.com     Application1
Old           http://www.stackoverflow3.com     Application2

The expected Output would be

New - Application 1 - (2)
    http://www.stackoverflow1.com
    http://www.stackoverflow2.com
Old - Application 2 - (1)
    http://www.stackoverflow3.com

This table represents an inventory of applications that are deployed on a company's network. An application can exist on multiple URLs, and be one of two versions, in this example “new” or “old “. The goal of the query I am having a problem with is to be able to provide a report where the Version, then Application, group the URLs so that one could see, for example, I have the “new” version of application “X” deployed at such and such URLs. In addition, I also need to provide the amounts/counts of URL's for each grouping of Versions and Application, for example the “new” version of application “X” appeared this many times (this data will eventually be exported from SQL to a spreadsheet).

Answer 1

You likely don't need to write any code.

Use the report wizard - it will group for you.

Assuming you have the table in Access. Just click on the table (highlight).

Then from ribbon create - choose the report wizard.

ORDER that you choose the fields is VERY important.

So, application, version, URL.

Group by Application, version.

Choose "stepped"

The report will look like this:

Now, you can save the report -

Now open report in design mode. Now from ribbon - choose Group and sort. Choose to add a sum - but choose your "new" column - it will offer a count due to this being a text value.

You get this:

And then you can move up the total box to the detail section.

You get this:

I suppose you could consider a SQL group by, but the sorting and grouping with the report writer can quite much group and total on rows of data just about anyway you want.

You can remove all the extra heading stuff and other junk - once done, then from the ribbon you can export to excel.

Answer 2

Below is some VBA code that uses two recordsets, one to get the "title" information for each group, and the other to get the detailed information for each group, and outputs it all to an Excel file:

Sub sExportAppData()
    On Error GoTo E_Handle
    Dim db As DAO.Database
    Dim rsMaster As DAO.Recordset
    Dim rsDetail As DAO.Recordset
    Dim strSQL As String
    Dim objXL As New Excel.Application
    Dim objXLBook As Excel.Workbook
    Dim objXLSheet As Excel.Worksheet
    Dim strXLFile As String
    Dim lngRow As Long
    strXLFile = "J:\downloads\app-data.xlsx"
    If Len(Dir(strXLFile)) > 0 Then Kill strXLFile
    Set db = DBEngine(0)(0)
    strSQL = "SELECT A.AppVersion, A.AppApplication, Count(A.AppApplication) AS AppFrequency " _
        & " FROM tblApplication A " _
        & " GROUP BY A.AppVersion, A.AppApplication " _
        & " ORDER BY A.AppVersion ASC, A.AppApplication ASC;"
    Set rsMaster = db.OpenRecordset(strSQL)
    If Not (rsMaster.BOF And rsMaster.EOF) Then
        Set objXLBook = objXL.Workbooks.Add
        Set objXLSheet = objXLBook.Worksheets(1)
        lngRow = 1            
        Do
            objXLSheet.Cells(lngRow, 1) = rsMaster!AppVersion & " - " & rsMaster!AppApplication & " - (" & rsMaster!AppFrequency & ")"
            lngRow = lngRow + 1
            strSQL = "SELECT AppURL FROM tblApplication " _
                & " WHERE AppVersion='" & rsMaster!AppVersion & "' AND AppApplication='" & rsMaster!AppApplication & "' " _
                & " ORDER BY AppURL ASC;"
            Set rsDetail = db.OpenRecordset(strSQL)
            If Not (rsDetail.BOF And rsDetail.EOF) Then
                Do
                    objXLSheet.Cells(lngRow, 1) = rsDetail!AppURL
                    lngRow = lngRow + 1
                    rsDetail.MoveNext
                Loop Until rsDetail.EOF
            End If
            rsMaster.MoveNext
        Loop Until rsMaster.EOF
        objXLBook.SaveAs strXLFile
    End If
sExit:
    On Error Resume Next
    rsDetail.Close
    rsMaster.Close
    Set rsDetail = Nothing
    Set rsMaster = Nothing
    Set objXLSheet = Nothing
    objXLBook.Close
    Set objXLBook = Nothing
    objXL.Quit
    Set objXL = Nothing
    Exit Sub
E_Handle:
    MsgBox Err.Description & vbCrLf & vbCrLf & "sExportAppData", vbOKOnly + vbCritical, "Error: " & Err.Number
    Resume sExit
End Sub

Regards,