将策略 Pine 脚本从 v2 转换为 v4，做到了，但得到了不同且错误的结果

Question

My original script is based on HeikinAshi strategy with certain conditions.

//@version=2
//Heikin Ashi Strategy  V2 by breizh29

strategy("Heikin Ashi Strategy  V2",shorttitle="HAS V2",overlay=true,default_qty_type=strategy.percent_of_equity, default_qty_value=100,initial_capital=100,currency=currency.GBP)
res = input(title="Heikin Ashi Candle Time Frame", type=resolution, defval="60")
hshift = input(1,title="Heikin Ashi Candle Time Frame Shift")
res1 = input(title="Heikin Ashi EMA Time Frame", type=resolution, defval="180")
mhshift = input(0,title="Heikin Ashi EMA Time Frame Shift")
fama = input(1,"Heikin Ashi EMA Period")
test = input(1,"Heikin Ashi EMA Shift")
sloma = input(30,"Slow EMA Period")
slomas = input(1,"Slow EMA Shift")
macdf = input(false,title="With MACD filter")
res2 = input(title="MACD Time Frame", type=resolution, defval="15")
macds = input(1,title="MACD Shift")




//Heikin Ashi Open/Close Price
ha_t = heikinashi(tickerid)
ha_open = security(ha_t, res, open[hshift])
ha_close = security(ha_t, res, close[hshift])
mha_close = security(ha_t, res1, close[mhshift])

//macd
[macdLine, signalLine, histLine] = macd(close, 12, 26, 9)
macdl = security(ha_t,res2,macdLine[macds])
macdsl= security(ha_t,res2,signalLine[macds])

//Moving Average
fma = ema(mha_close[test],fama)
sma = ema(ha_close[slomas],sloma)
plot(fma,title="MA",color=lime,linewidth=2,style=line)
plot(sma,title="SMA",color=red,linewidth=2,style=line)


//Strategy
golong =  crossover(fma,sma) and (macdl > macdsl or macdf == false )
goshort =   crossunder(fma,sma) and (macdl < macdsl or macdf == false )

strategy.entry("Buy",strategy.long,when = golong)
if (goshort)
    strategy.close("Buy")

and my compiled script to v4 is

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © Stopperbg

//@version=4

strategy("HAS V3",shorttitle="HAS V3",overlay=true,default_qty_type=strategy.percent_of_equity, default_qty_value=100,initial_capital=1000,currency=currency.USD)
res = input(title="Heikin Ashi Candle Time Frame", type=input.resolution, defval="60")
hshift = input(1,title="Heikin Ashi Candle Time Frame Shift")
res1 = input(title="Heikin Ashi EMA Time Frame", type=input.resolution, defval="180")
mhshift = input(0,title="Heikin Ashi EMA Time Frame Shift")
fama = input(1,"Heikin Ashi EMA Period")
test = input(1,"Heikin Ashi EMA Shift")
sloma = input(30,"Slow EMA Period")
slomas = input(1,"Slow EMA Shift")
macdf = input(false,title="With MACD filter")
res2 = input(title="MACD Time Frame", type=input.resolution, defval="15")
macds = input(1,title="MACD Shift")




//Heikin Ashi Open/Close Price
t = tickerid(syminfo.prefix, syminfo.ticker, session.regular)
ha_t = heikinashi(t)
ha_open = security(ha_t, res, open[hshift])
ha_close = security(ha_t, res, close[hshift])
mha_close = security(ha_t, res1, close[mhshift])

//macd
[macdLine, signalLine, histLine] = macd(close, 12, 26, 9)
macdl = security(ha_t,res2,macdLine[macds])
macdsl= security(ha_t,res2,signalLine[macds])

//Moving Average
fma = ema(mha_close[test],fama)
sma = ema(ha_close[slomas],sloma)
plot(fma,title="MA",color=color.lime,linewidth=2,style=plot.style_line)
plot(sma,title="SMA",color=color.red,linewidth=2,style=plot.style_line)


//Strategy
golong =  crossover(fma,sma) and (macdl > macdsl or macdf == false )
goshort =   crossunder(fma,sma) and (macdl < macdsl or macdf == false )

strategy.entry("Buy",strategy.long,when = golong)
if (goshort)
    strategy.close("Buy")

I followed tutorials and my script is without errors. I do this conversion, because I want to add alertcondition to get alarm when condition is met.

On v2 there is no alert with added buy or sell signal, Please note that in Pine v4 an alertcondition call generates an additional plot. All such calls are taken into account when we calculate the number of the output series per script. But I got different results. whats wrong with it?

Answer 1

That script is misleading and producing unrealistic results.

Using the default settings, the code is cheating by using future data to calculate the fma variable used to trigger Buy/Sell orders. If hshift == 0 or mhshift == 0 (the default), then your script will be using future data, and so misleading traders or you.

To avoid this, you should change these lines:

hshift = input(1,title="Heikin Ashi Candle Time Frame Shift")
mhshift = input(0,title="Heikin Ashi EMA Time Frame Shift")

to:

hshift = input(1,title="Heikin Ashi Candle Time Frame Shift", minval = 1)
mhshift = input(1,title="Heikin Ashi EMA Time Frame Shift", minval = 1)

See How to avoid repainting when using security() - PineCoders FAQ for more details.

Note that the scripts using the source code you reused have been moderated a while back for the exact reason that they were misleading.

Answer 2

so i manage to fix it. added lookahead=barmerge.lookahead_on

ha_open = security(ha_t, res, open[hshift], lookahead=barmerge.lookahead_on)
ha_close = security(ha_t, res, close[hshift], lookahead=barmerge.lookahead_on)
mha_close = security(ha_t, res1, close[mhshift], lookahead=barmerge.lookahead_on)

they changed lookahead to off by default