查找并删除一行 Excel VBA 代码

Question

I have an Excel spreadsheet that has several modules with multiple sub procedures. One module has the multiple procedures and another module Calls each of those procedures. The problem is that the list of Call Subs will vary. I know how to add to the below routine, but I can't figure out how to delete a line, based off of what I enter in a cell in the worksheet. The process would be to enter "Call TMS1707455" in a cell, then run a macro that would delete the value of that cell from the below sub.

Sub TMS()

    Call TMS1707455
    Call TMS1367006
    Call TMS4268798
    Call TMS1366994
    Call TMS39522
    Call TMS39523
    Call TMS4482313
    Call TMS19395
    Call TMS39415
    Call TMS37118
End Sub

Or, would it be better or possible to enter this list of Call Subs in a worksheet column. I could then modify the list as needed and have a macro that would call all of the procedures based on the column of call subs. This way, I wouldn't have to have a macro to add lines and a macro to delete lines. I just can't find any info on how to do either ways.

Answer 1

Something like this will help you a lot and I think the example demonstrates many programming principles that will help you write more efficient/manageable/editable code moving forward. Note the comments as well.

Option Explicit

Sub TMS()

    cleanUp "TMS1707455"
    cleanUp "TMS1367006"
    '... etc
    'add / delete comment as needed

End Sub

Sub cleanUp(which As String)

    Dim findIt As String, changeTo As String

    Select Case which

        Case Is = "TMS1707455"
            findIt = "1707455(HSPD-12 Sponsor Certification Training)": changeTo = "HSPD-12 Sponsor Certification Training"
        Case Is = "TMS1367006"
            findIt = "1367006(VA Telework Training Module For Employees)": changeTo = "VA Telework Training Module For Employees"
        'Case Is = ' ... next in line '
        'delete cases as needed, or comment them out

    End Select

    Dim ws As Worksheet
    Set ws = Worksheets("mySheet") 'always explicitly declare and work directly with objects

    ws.Cells.Replace What:=findIt, Replacement:=changeTo
    'i would also suggest only working with the cells with actual data you need,
        'like the columnset or row set, it will speed up the code, especially using Replace

End Sub

Answer 2

I figured out what I needed to do. The below code deletes one line of my macro, depending on the value in a cell. I found the answer here: http://www.cpearson.com/excel/vbe.aspx It may not be pretty, but it works.

    Dim VBProj As VBIDE.VBProject
    Dim VBComp As VBIDE.VBComponent
    Dim CodeMod As VBIDE.CodeModule
    Dim FindWhat As String
    Dim SL As Long ' start line
    Dim EL As Long ' end line
    Dim SC As Long ' start column
    Dim EC As Long ' end column
    Dim Found As Boolean

    Set VBProj = ActiveWorkbook.VBProject
    Set VBComp = VBProj.VBComponents("Module2")
    Set CodeMod = VBComp.CodeModule

    FindWhat = [C21]

    With CodeMod
        SL = 7
        EL = .CountOfLines
        SC = 1
        EC = 255
        Found = .Find(target:=FindWhat, StartLine:=SL, StartColumn:=SC, _
            EndLine:=EL, EndColumn:=EC, _
            wholeword:=True, MatchCase:=False, patternsearch:=False)
        If Found = True Then
            .DeleteLines StartLine:=SL
        End If
    End With