SAS 数组循环（做while循环）

Question

data JE.KeywordMatchTemp1;
  if _n_ = 1 then do;
    do i = 1 by 1 until (eof);
      set JE.KeyWords end=eof;
      array keywords[100] $30 _temporary_;
      keywords[i] = Key_Words;
    end;
    last_i = i ;
    retain last_i ;
  end;
  set JE.JEMasterTemp;
  match = 0;
  do i = 1 to last_i while (match=0) ;
    if index(descr, trim(keywords[i]) ) then match = 1;
  end;
  drop i last_i;
run;

Hi Can I ask what does this statement does if _n_ = 1 then do;

I have tried deleting this statement and the set statement set JE.JEMasterTemp; only reading in 1 observation.

I need help...

Answer 1

The _ N _ Variable represents the number of times the DATA step has iterated. You can read more about it here: Automatic Variables . So, on the first iteration only, you:

• Read the JE.Keywords data set one obs at the time and increments the variable i for each obs.

• inserts the Key_Words value into the i'th place in the keywords array.

• Assigns the value of i to the variable last_i when the entire JE_Keywords has been read.

Answer 2

One thing to remember is that most data steps do not stop at the end of the data step. Instead they stop when they read past the end of the input (either in INPUT statement or a SET/MERGE statement).

The _N_ automatic variable is incremented once per data step iteration. So _N_=1 is a test for whether this is the first iteration. The data step is designed to read ALL of KEYWORDS on the first iteration. And then to read one observations from JEMASTERTEMP per iteration. So normally the data step stops when it reads past the end of JEMASTERTEMP.

By removing that line what happens on the second iteration is that it will try to read more observations from KEYWORDS, but it read all of the observations on the first iteration. So without that IF statement the step stops at the top of the second iteration, so only one observation is written.