用 Cython 包装 C header 宏

Question

I am writing a Cython wrapper for the NAG C library.

In one of the header files from the NAG C library is the macros:

#define NAG_FREE(x) x04bdc((Pointer *)&(x))

Pointer is void*

x04bdc is:

extern void NAG_CALL x04bdc(Pointer *ptr);

NAG_FREE is the NAG library equivalent of free(), to free up memory.

Here is the extract from my lib_nag_integrate.pxd file:

cdef extern from "<nagx04.h>":
    void x04bdc(Pointer *ptr)

x04bdc is a "fancy" free (malloc) routine. I cant access this code.

I then create a cdef function in my.pyx file:

cdef void NAG_FREE(double *x):
    x04bdc(<Pointer *>&x)

Here i have type casted x to a double pointer, as that is what I am trying to free from memory, however the NAG library examples seem to use it for any type of pointer.

When running the python script which calls a cpdef function which eventually uses NAG_FREE, I get the following error:

Process finished with exit code 134 (interrupted by signal 6: SIGABRT)

If i comment out the NAG_FREE calls then it works fine, however NAG say it is necessary to use NAG_FREE.

The cdef function using NAG_FREE is:

cdef (double,double,Integer,Integer) dim1_fin_gen(lib_nag_integrate.NAG_D01SJC_FUN objfun,double a, double b,double epsabs, double epsrel,
                         Integer max_num_subint,Nag_User *comm,integration_out *output):
    """

    :param f: user function
    :type f: function
    :param a: lower limit of integration
    :type a: real float
    :param b: upper limit of integration
    :type b: real float
    :param epsabs: user requested absolute error
    :type epsabs: integer
    :param epsrel: user requested relative error
    :type epsrel: integer
    :param max_num_subint: maximum number of subintervals
    :type max_num_subint: real integer
    :return: integration value of user function f
    :rtype: real float
    """

    cdef lib_nag_integrate.Nag_QuadProgress _qp
    cdef lib_nag_integrate.NagError _fail
    cdef double result
    cdef double abserr


    _fail.print = True
    _fail.code = 0
    _fail.errnum = 0
    _fail.handler = NULL

    lib_nag_integrate.d01sjc(objfun, a, b, epsabs, epsrel,
                             max_num_subint, &result, &abserr,
                    &_qp, comm, &_fail)
    if _fail.code > 0 :
        errorMessage = _fail.message
        raise NagException(_fail.code,errorMessage)
        print(_fail.message)

    else:
        output[0].result = result
        output[0].abserr = abserr
        output[0].fun_count = _qp.fun_count
        output[0].num_subint = _qp.num_subint

        NAG_FREE(_qp.sub_int_beg_pts)
        NAG_FREE(_qp.sub_int_end_pts)
        NAG_FREE(_qp.sub_int_result)
        NAG_FREE(_qp.sub_int_error)

My libnag_integrate.pxd header file imports the following from the c library:

cdef extern from "<nag_types.h>":
    ctypedef bint Nag_Boolean
    ctypedef long Integer
    ctypedef void* Pointer
    ctypedef struct NagError:
        int code
        bint print "print"
        char message[512]
        Integer errnum
        void (*handler)(char*,int,char*)
    ctypedef struct Nag_User:
        Pointer p
    ctypedef struct Nag_QuadProgress:
        Integer num_subint
        Integer fun_count
        double *sub_int_beg_pts
        double *sub_int_end_pts
        double *sub_int_result
        double *sub_int_error

cdef extern from "<nagx04.h>":
    (void*) NAG_ALLOC "x04bjc" (size_t size)
    void x04bdc(Pointer *ptr)


cdef extern from "<nagd01.h>":
    void d01sjc(NAG_D01SJC_FUN f, double a, double b,
         double epsabs, double epsrel, Integer max_num_subint, double *result,
         double *abserr, Nag_QuadProgress *qp, Nag_User *comm,
         NagError *fail)

d01sjc is an integration routine which I cannot access. It allocates the memory of qp.sub_int_beg_pts etc inside.

I think I have a corrupt pointer causing the error. If so, where is it and how to I fix it?

many thanks

Upon further inspection of the structure '_qp'. The same error occurs when dereferencing eg:

x = _qp.sub_int_end_pts[0]

so its the dereferencing of _qp which is causing the error.

The struct type Nag_QuadProgress is imported from its NAG header file into my.pxd as follows:

cdef extern from "<nag_types.h>":
ctypedef struct Nag_QuadProgress:
        Integer num_subint
        Integer fun_count
        double *sub_int_beg_pts
        double *sub_int_end_pts
        double *sub_int_result
        double *sub_int_error

Any ideas why dereferencing the pointers in this structure causes the error?

Answer 1

From Cython's point of view you're using NAG_FREE as a function, so that's what you should declare it as. It doesn't really matter that it's a really macro, and it certainly doesn't help to attempt to reimplement it.

cdef extern from "whatever_the_nag_header_is":
    void NAG_FREE(Pointer x)
    # or
    void NAG_FREE(void *x)
    # or
    void NAG_FREE(...)  # accepts anything - Cython doesn't attempt to match types

You may have to play around a bit with the type of the arguments to get it to work - I've suggested three options.

Really all you're aiming to do is to give Cython enough information that it can generate the right C code, and the right C code is NAG_FREE(your_variable) , as if it's a function call.

---

With your code:

• (<integration_out*>output)[0] suggests you're doing something very wrong. output is an integration_out pointer so why are you casting it? It either does nothing or introduces a potential error.

• Despite claiming to return a C tuple type you actually don't bother to return anything.