如何获取当前构建已从阶段重新启动的构建 ID？

Question

I've a Jenkins pipeline and it has 5 stages. Suppose I run it and it has build id 5, but it fails at 3rd stage.

Now I re-run build 5 using Restart from failed stage feature and current build is with id 7(as meanwhile someone ran with id 6). NOw in current running build with id 7, I want to get id(which is 5) of build from which this build has restarted.

Is there any api using which I can get an id of build from which current build has restarted?

Answer 1

You can get this information through currentBuild.rawBuild.getCause(RestartDeclarativePipelineCause) :

Working pipeline example:

pipeline{
    agent any

    stages {
        stage('Stage 1') {
            steps {
                echoRestartedInfo()
            }
        }
        stage('Stage 2') {
            steps {
                echoRestartedInfo()
            }
        }
    }
}

void echoRestartedInfo() {
    def restartCause = currentBuild.rawBuild.getCause(
        org.jenkinsci.plugins.pipeline.modeldefinition.causes.RestartDeclarativePipelineCause )

    if( restartCause ) {
        def originRunNumber = restartCause.originRunNumber
        def originStage     = restartCause.originStage
        echo "Restarted from build $originRunNumber, stage '$originStage'"
    }
    else {
        echo "Normal run"
    }
}

Because of using rawBuild this doesn't work in sandbox. Move the code into a shared library to work around this restriction.