delphi class 在运行时确定

Question

Is there a way in Delphi XE+ to create a function whose result is determined at runtime?

For example:

function ARuntimeClass(achoice: integer): ClassType;
begin
   case achoice of
     0: Result := TEdit;
     1: Result := TMemo;
     2: Result := TCheckbox;
     3: Result := TComboBox;
   end;
end;

Then, at runtime:

var
  aComponent: TComponent;       
begin
  aComponent := FindComponent('SomeComponent234');
  //then process
  ARuntimeClass(2).Checked := True;
  aComponent := FindComponent('SomeComponent123');
  //then process
  ARuntimeClass(0).Text := 'Chosen';    
end;

I am trying to typecast at runtime.

Answer 1

Yes, you can return a class type as a function result, using a metaclass type likeSystem.TClass (represents all class types), Classes.TComponentClass (represents classes derived from TComponent ), TControlClass (represents all classes derived from TControl ), etc.

function ARuntimeClass(achoice: integer): TControlClass;
begin
  case achoice of
    0: Result := TEdit;
    1: Result := TMemo;
    2: Result := TCheckbox;
    3: Result := TComboBox;
  end;
end;

Although, you can simply use aComponent.ClassType() instead to access the object's real metaclass type, you don't need a separate function for that.

However, just having access to a metaclass type doesn't actually solve your issue. You can't use a metaclass to typecast an object pointer to access any type-specific members. For what you are attempting, you need to use RTTI instead, eg:

Using old-style RTTI (pre-D2010):

uses
  ..., TypInfo;

var
  aComponent: TComponent;       
  aProp: PPropInfo;
begin
  aComponent := FindComponent('SomeComponent234');
  //then process
  pProp := GetPropInfo(aComponent, 'Checked');
  if aProp <> nil then SetOrdProp(aComponent, aProp, True);

  aComponent := FindComponent('SomeComponent123');
  //then process
  aProp := GetPropInfo(aComponent, 'Text');
  if aProp = nil then aProp := GetPropInfo(aComponent, 'Caption');
  if aProp <> nil then SetStrProp(aComponent, aProp, 'Chosen');
end;

Using new-style enhanced RTTI (D2010+):

uses
  ..., System.Rtti;

var
  aComponent: TComponent;       
  ctx: TRttiContext;
  rType: TRttiType;
  rProp: TRttiProperty;
begin
  aComponent := FindComponent('SomeComponent234');
  //then process
  rType := ctx.GetType(aComponent.ClassType);
  rProp := rType.GetProperty('Checked');
  if rProp <> nil then rProp.SetValue(aComponent, True);

  aComponent := FindComponent('SomeComponent123');
  //then process
  rType := ctx.GetType(aComponent.ClassType);
  rProp := rType.GetProperty('Text');
  if rProp = nil then rProp := rType.GetProperty('Caption');
  if rProp <> nil then rProp.SetValue(aComponent, 'Chosen');
end;