如何编写 LAG() Function 以计算 PROC SQL SAS 中的日期差异

Question

I am trying to write a code in SQL SAS to calculate difference of days when a user was seen.

As an example of a raw data is following:

USER     DATE
User1    20200516
User1    20200513
User1    20200501
User2    20200515
User2    20200511

How to write a LAG() Function so the output table should look like following:

USER     DATE       PREV_DATE    DIFF
User1    20200516   20200513     3
User1    20200513   20200501     12
User2    20200515   20200511     4

Answer 1

I don't use sas so please take my answer as hint for usage of lag function, other issues such as date conversion or computing difference is up to you. This is solution in Postgres (columns renamed to avoid clashes):

with t(user_col,date_col) as (values
  ('User1', date '2020-05-16'),
  ('User1', date '2020-05-13'),
  ('User1', date '2020-05-01'),
  ('User2', date '2020-05-15'),
  ('User2', date '2020-05-11')
), lags as (
  select user_col
       , date_col
       , lag(date_col) over (partition by user_col order by date_col) as prev_date
  from t
)
select user_col, date_col, prev_date, date_col - prev_date as diff
from lags
where prev_date is not null
order by user_col asc, date_col desc

Dbfiddle here.

Please for the next time, provide sample input as CTE (with clause) directly in question.

Answer 2

SQL does not have the concept of LAG baked in and SAS SQL does not implement windowed functions or CTEs

The result set you want can be obtained using a reflexive join and SAS SQL automatic remerge feature.

data have;
attrib
  user length=$8
  date length= 8 format=yymmdd10. informat=yymmdd10.
;
input USER DATE;
datalines;
User1    20200516
User1    20200513
User1    20200501
User2    20200515
User2    20200511
;

proc sql;
  create table want as
  select 
    LEFT.user
  , LEFT.date
  , RIGHT.date as PREV_DATE
  , LEFT.date - RIGHT.date as DIFF
  from
    have as LEFT
  left join
    have as RIGHT
  on
    LEFT.user = RIGHT.user
  where
    LEFT.date > RIGHT.date
  group by
    LEFT.date
  having
    DIFF = MIN(DIFF)
  order by
    LEFT.user, LEFT.date desc, RIGHT.date desc
  ; 

Answer 3

Here is a data step approach

data have;
input USER $ DATE :anydtdte.;
format date yymmddn8.;
datalines;
User1 20200516
User1 20200513
User1 20200501
User2 20200515
User2 20200511
;

data want;
    merge have
          have(firstobs=2 rename=(date=prev_date user=_user));
    if user=_user;
    diff=date-prev_date;
    drop _:;
run;