如何使用 F# 中的 ZeroLog？

Question

I could not find any details on this.

Here is the code:

// external
open ZeroLog
open ZeroLog.Appenders
open ZeroLog.Config
open System.Collections.Generic
// internal

module Logging =  

  let logManager =
    let appender = new ConsoleAppender()
    let defaultAppenderConfig = DefaultAppenderConfig()
    defaultAppenderConfig.PrefixPattern <- "[%level] @ %time - %logger :: "
    appender.Configure(defaultAppenderConfig)
    let appenders =  new List<IAppender>(capacity=1)
    appenders.Add(appender)
    BasicConfigurator.Configure(appenders)  

  let getLogger (name:string) =
    LogManager.GetLogger(name)

  let testLogging () =
    let logger = getLogger "Main"
    logger.Info("test")

It compiles but when I try to use testLogging it does not print anything. Maybe I need to configure some additional details but I am not sure what.

Answer 1

Static initializer for Logging.fs file is not being called ( 12.5.1 Execution of Static Initializers ) because it's not an entry point file and you are not accessing any value which has observable initialization (yes, that's a vague definition). The point is - if static initializer wasn't called, then logManager value wasn't initialized. Which means in your case that all logger configuration code wasn't executed.

The simplest way to make sure logger is initialized is to move initialization logic to function and call it explicitely:

let init () =
    let appender = new ConsoleAppender()
    let defaultAppenderConfig = DefaultAppenderConfig()
    defaultAppenderConfig.PrefixPattern <- "[%level] @ %time - %logger :: "
    appender.Configure(defaultAppenderConfig)
    let appenders = new List<IAppender>(capacity=1)
    appenders.Add(appender)
    BasicConfigurator.Configure(appenders) |> ignore

Make sure you call it at the top of Main before you use logging

Logging.init()
Logging.testLogging()

Note that even direct access to logManager value will trigger static initializer only in Debug mode (because of unused values optimizations in Release mode):

let _ = Logging.logManager // works in Debug only
Logging.testLogging()