如何从文件中读取内容并将其存储在 clojure 的哈希映射中？

Question

I got a small problem in clojure. I am new to this programming environment and need a little help. I have got a text file in this format:

1|John Smith|123 Here Street|456-4567
2|Sue Jones|43 Rose Court Street|345-7867
3|Fan Yuhong|165 Happy Lane|345-4533

I want to parse each line in file and want to store data in hashmap in this way:

{ 1 : [John Smith, 123 here street, 456-4567], 2 : ... }

Here is my code till now but I have not got any success.

(defn readcustfile[]
  (def cust-file (clojure.string/split-lines (slurp "cust.txt"))) 

  (doseq [line cust-file]
    (def cust-id (nth (clojure.string/split line #"\|") 0))
    (def cust-name (str (nth (clojure.string/split line #"\|") 1)))
    (def cust-add (str (nth (clojure.string/split line #"\|") 2)))
    (def cust-phone (str (nth (clojure.string/split line #"\|") 3)))
    (def cust-data (str cust-name "," cust-add "," cust-phone))
    (def cust (map (fn [[id name add phone]]
                     (list (Integer/parseInt cust-id)
                           (hash-map :name cust-name
                                     :add cust-add
                                     :phone cust-phone))
    )
  )
(readcustfile)

Answer 1

what i would propose, is to read file line by line transducing it into resulting map in one pass:

(require '[clojure.java.io :refer [reader]]
         '[clojure.string :as cs]
         '[clojure.edn :as edn])

(with-open [rdr (reader "data.csv")]
  (into {}
        (map (comp (juxt (comp edn/read-string first) rest)
                   #(cs/split % #"\|")))
        (line-seq rdr)))

;;=> {1 ("John Smith" "123 Here Street" "456-4567"),
;;    2 ("Sue Jones" "43 Rose Court Street" "345-7867"),
;;    3 ("Fan Yuhong" "165 Happy Lane" "345-4533")}

notice, you don't have to read the whole file into memory, rather you use with-open reader + line seq .

notice also, the form of into + map (the transducer) is used instead of simple map then into {} or for , to avoid intermediate collection creation.

Answer 2

You should use a library to read CSV data. Here is another one .

Here is an example:

(ns tst.demo.core
  (:use tupelo.core tupelo.test)
  (:require
    [tupelo.csv :as csv]
    ))

; use (slurp <filename>) to read data into a string
(def data-str
  "id|name|address|phone
   1|John Smith|123 Here Street|456-4567
   2|Sue Jones|43 Rose Court Street|345-7867
   3|Fan Yuhong|165 Happy Lane|345-4533 ")

Note that I added a header line to describe the fields of each CSV record. Unit tests show the result:

(dotest
  (let [entity-maps (csv/parse->entities data-str :delimiter \|)
        grouped     (group-by :id entity-maps)]

    (is= entity-maps
      [{:id      "1",
        :name    "John Smith",
        :address "123 Here Street",
        :phone   "456-4567"}
       {:id      "2",
        :name    "Sue Jones",
        :address "43 Rose Court Street",
        :phone   "345-7867"}
       {:id      "3",
        :name    "Fan Yuhong",
        :address "165 Happy Lane",
        :phone   "345-4533"}])

    (is= grouped
      {"1"
       [{:id      "1",
         :name    "John Smith",
         :address "123 Here Street",
         :phone   "456-4567"}],
       "2"
       [{:id      "2",
         :name    "Sue Jones",
         :address "43 Rose Court Street",
         :phone   "345-7867"}],
       "3"
       [{:id      "3",
         :name    "Fan Yuhong",
         :address "165 Happy Lane",
         :phone   "345-4533"}]})))

Be sure to see this list of documentation , especially the Clojure CheatSheet.

Answer 3

(def cust-file ["1|John Smith|123 Here Street|456-4567"
                "2|Sue Jones|43 Rose Court Street|345-7867"
                "3|Fan Yuhong|165 Happy Lane|345-4533"])

(into {}                      ;; construc new hash map from coll
                              ;; (into {} ["key" "data"]) => {"key" "data"}
      (for [line cust-file    ;; `for` instead of `doseq`
                              ;; (`doseq` will return nil, but `for` - results of iteration)
            :let [[id & data] ;; shortend `let` alias, use desctructjion to get `id` and rest as `data`
                  (clojure.string/split line #"\|")]]
        [(Integer/parseInt id) data])) ;; return pair [id [name add phone]] for every line

;; => {1 ("John Smith" "123 Here Street" "456-4567"),
;;     2 ("Sue Jones" "43 Rose Court Street" "345-7867"),
;;     3 ("Fan Yuhong" "165 Happy Lane" "345-4533")}