在VBA中，如何从文本中提取数字前的字符串

Question

From ActiveWorkbook.name , I would like to extract the strings that are before (left side of ) the numbers. Since I want to use the same code in multiple workbooks, the file names would be variable, but every file name has date info in the middle (yyyymmdd).

In case of excel file, I can use the below formula, but can I apply the same kind of method in VBA?

=LEFT(A1,MIN(FIND({0,1,2,3,4,5,6,7,8,9},ASC(A1)&1234567890))-1)

Example: MyExcelWorkbook_Management_20200602_MyName.xlsm

In above case, I want to extract "MyExcelWorkbook_Management_".

Answer 1

You could use Regular Expressions to extract any letters / underscores before the number as well

Dim str As String

str = "MyExcelWorkbook_Management_20200602_MyName.xlsm"

With CreateObject("vbscript.regexp")
    .Pattern = "^\D*"
    .Global = True

    MsgBox .Execute(str)(0)
End With

Gives:

MyExcelWorkbook_Management_

Answer 2

The most basic thing you could do is to replicate something that worked for you in Excel through Evaluate :

Sub Test()
    Dim str As String: str = "MyExcelWorkbook_Management_20200602_MyName.xlsm"
    Debug.Print Evaluate(Replace("=LEFT(""X"",MIN(FIND({0,1,2,3,4,5,6,7,8,9},ASC(""X"")&1234567890))-1)", "X", str))
End Sub

Pretty? Not really, but it does the job and got it's limitations.

Answer 3

So basically you want to use the Mid function to look for the first numerical character in your input string, and then cut your input string to that position. That means we need to loop through the string from left to right, look at one character at a time and see if it is a digit or not. This code does exactly that:

Option Explicit

Sub extratLeftText()

Dim someString As String
Dim result As String
someString = "Hello World1234"

Dim i As Long
Dim c As String 'one character of your string

For i = 1 To Len(someString)
    c = Mid(someString, i, 1)
    If IsNumeric(c) = True Then 'should write  "If IsNumeric(c) = True AND i>1 Then" to avoid an "out of bounds" error
        result = Left(someString, i - 1)
        Exit For
    End If
Next i

MsgBox result
End Sub

Last thing you need to do is to load in some workbook name into your VBA function. Generally this is done with the .Name method of the workbook object:

Sub workbookName()

Dim wb As Workbook
Set wb = ActiveWorkbook

MsgBox wb.Name

End Sub

Of course you would need to find some way to replace the Set wb = ActiveWorkbook line with code that suits your purpose.