如何使用 XSLT 基于输入 XML 请求的相同属性从 XML 文件中删除公共节点？

Question

I have two XMLs:

XML1.xml which will be as an input request.

<ConnectorConfig>
<service uri="/gen5">
<routeUrl>http://localhost:3003/v1</routeUrl>
</service>
<service uri="/gen6">
<routeUrl>http://localhost:3003/v61</routeUrl>
</service>
</ConnectorConfig> 

XML2.xml which will be stored xml file.

<ConnectorConfig>
<service uri="/gen5">
<routeUrl>http://localhost:3003/v5</routeUrl>
</service>
<service uri="/gen6">
<routeUrl>http://localhost:3003/v6</routeUrl>
</service>
<service uri="/gen7">
<routeUrl>http://localhost:3003/v7</routeUrl>
</service>
<service uri="/gen8">
<routeUrl>http://localhost:3003/v7</routeUrl>
</service>
</ConnectorConfig>

Output which i need is to get all the elements of XML2.xml except for the element having same service attribute in XML1.xml .

Desired Output:

<ConnectorConfig>
    <service uri="/gen7">
        <routeUrl>http://localhost:3003/v7</routeUrl>
    </service>
    <service uri="/gen8">
        <routeUrl>http://localhost:3003/v7</routeUrl>
    </service>
</ConnectorConfig>

This is what i tried.

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output indent="yes" omit-xml-declaration="yes"/>

  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()" />
    </xsl:copy>
  </xsl:template>

  <xsl:template match="ConnectorConfig">
  <xsl:copy> 
     <xsl:variable name="item" select="document('XML2.xml')/ConnectorConfig"/>  
     <xsl:variable name="current" select="."/> 

   <xsl:for-each select="$item/service"> 
      <xsl:variable name="savedUri" select="@uri"/> 
 
        <xsl:if test="$current/service[@uri!=$savedUri]">
          <xsl:apply-templates select="."/>
        </xsl:if> 

   </xsl:for-each>  
  </xsl:copy>
  </xsl:template>

 </xsl:stylesheet>

Output which i got for input request XML1.xml is:

<ConnectorConfig>
    <service uri="/gen5">
        <routeUrl>http://localhost:3003/v5</routeUrl>
    </service>
    <service uri="/gen6">
        <routeUrl>http://localhost:3003/v6</routeUrl>
    </service>
    <service uri="/gen7">
        <routeUrl>http://localhost:3003/v7</routeUrl>
    </service>
    <service uri="/gen8">
        <routeUrl>http://localhost:3003/v7</routeUrl>
    </service>
</ConnectorConfig> 

But when i tried for same implementation with input XML1a.xml as:

<ConnectorConfig>
<service uri="/gen5">
<routeUrl>http://localhost:3003/v1</routeUrl>
</service>
</ConnectorConfig> 

I received desired output which is shown below.

<ConnectorConfig>
    <service uri="/gen6">
        <routeUrl>http://localhost:3003/v6</routeUrl>
    </service>
    <service uri="/gen7">
        <routeUrl>http://localhost:3003/v7</routeUrl>
    </service>
    <service uri="/gen8">
        <routeUrl>http://localhost:3003/v7</routeUrl>
    </service>
</ConnectorConfig>

In above, the output result contains all the elements of XML2.xml except one having /gen5 as common attribute for service element in input XML1a.xml .

From the above what i came to known is that for single service element in input request, i'm getting the desired result but for multiple elements its fails.

What is the mistake i'm doing? Please help.

Answer 1

How about simply:

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output indent="yes" omit-xml-declaration="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="ConnectorConfig">
    <xsl:variable name="local-uris" select="service/@uri" />
    <xsl:copy> 
        <xsl:copy-of select="document('XML2.xml')/ConnectorConfig/service[not(@uri=$local-uris)]"/>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

---

Note that the predicate:

[not(@uri=$local-uris)]

is not the same as:

[@uri!=$local-uris]

The former passes only nodes whose uri does not have a matching value in $local-uris .

The latter passes any node whose uri is not equal to at least one uri in $local-uris . In the given example, all nodes pass this test. If you reduce $local-uris to a single value, then all nodes will pass this test except the one that is equal to the single value. This should explain your own observations.