我想让这个 VBA 代码不区分大小写

Question

Function SingleCellExtract(LookupValue As String, LookupRange As Range, ColumnNumber As Integer, Char As String)
    'Updateby Extendoffice
    Dim I As Long
    Dim xRet As String
    For I = 1 To LookupRange.Columns(1).Cells.Count
        If LookupRange.Cells(I, 1) = LookupValue Then
            If xRet = "" Then
                xRet = LookupRange.Cells(I, ColumnNumber) & Char
            Else
                xRet = xRet & "" & LookupRange.Cells(I, ColumnNumber) & Char
            End If
        End If
    Next
    SingleCellExtract = Left(xRet, Len(xRet) - 1)
End Function

Answer 1

Two more ways besides the provided answer.

WAY 1

Type Option Compare Text at the very top. For example

Option Compare Text

Sub Sample()
    Dim stringA As String, stringB As String
    
    stringA = "sid"
    stringB = "SiD"
    
    MsgBox stringA = stringB
End Sub

You can read more about it in Option Compare Statement

Way 2

Convert it to uppercase or lower case and then compare

If UCase(LookupRange.Cells(I, 1).Value) = UCase(LookupValue) Then

'~~> OR

If LCase(LookupRange.Cells(I, 1).Value) = LCase(LookupValue) Then

Answer 2

Change the line If LookupRange.Cells(i, 1) = LookupValue Then to

If StrComp(LookupRange.Cells(i, 1), LookupValue, vbTextCompare) = 0 Then