谷歌表 ImportXML 失败

Question

This one works:

=importxml("https://discgolfmetrix.com/?u=scorecard&ID=900113&view=result", "//table[@class='data data-hover']/tr/td[2]")

This one fails:

=importxml("https://discgolfmetrix.com/?u=scorecard&ID=1172639&view=result", "//table[@class='data data-hover']/tr/td[2]")

If it was the other way around I could understand it, since the first one has 2 tbody tags.

Answer 1

GoogleSheets parses the page in its own way (parent >> child structure is not exactly the same as in your browser). Use //tr in your XPath to circumvent parsing errors:

=IMPORTXML("https://discgolfmetrix.com/?u=scorecard&ID=1172639&view=result","//table[@class='data data-hover']//tr/td[2]")

Or use IMPORTHMTL and QUERY :

=QUERY(IMPORTHTML("https://discgolfmetrix.com/?u=scorecard&ID=1172639&view=result","table",1),"select Col2 OFFSET 1")

Output:

EDIT : More details:

For the first link, the parsed HTML structure is the following one:

<table>
    <tr>    
        <td></td>
        <td>your_data</td>
        ...
    </tr>
    <tr>    
        <td></td>
        <td>your_data</td>
        ...
    </tr>
    ...
</table>

And your XPath works.

For the second link, there's a preceding tbody element which contains the tr elements. The structure is:

<table>
    <tbody>     
        <tr>    
            <td></td>
            <td>your_data</td>
            ...
        </tr>
        <tr>    
            <td></td>
            <td>your_data</td>
            ...
        </tr>
        ...
    </tbody>
</table>

And your XPath fails. That's why you have to use // or declare the tbody element in your expression:

=IMPORTXML("https://discgolfmetrix.com/?u=scorecard&ID=1172639&view=result","//table[@class='data data-hover']/tbody/tr/td[2]")