Zxing.Net 读取二维码

Question

I am using the Zxing.Net library to generate QR codes. I update each users QRcode on a daily basis, based on answers to a daily health survey. If it is a new user, the QRCode is created for the first time on the web server. If the file already exists, it just writes over it.

I have begun using the ReadQRCode() sub in a different process to read the QR code and display the data. However, after doing so, I can no longer update the QR code as it is "being used by another process". This only happens when I use the ReadQRCode() sub to read/decode the QR to a web page. The only way I have been able to remove this "file lock" is by restarting the web server.

Generate the QRCode which is not the issue:

  Public Sub GenerateCode(name As String)
        Dim intLoc As Integer
        Dim strFileName As String

        intLoc = Strings.InStr(name, "_")
        strFileName = name.Substring(0, intLoc - 1)
        name = name.Trim()
        Dim writer = New BarcodeWriter()
        writer.Format = BarcodeFormat.QR_CODE
        Dim result = writer.Write(name)
        Dim path As String = Server.MapPath("~/qrCodeImages/" & strFileName & ".jpg")
        Dim barcodeBitmap = New Bitmap(result)

        Using memory As New MemoryStream()
            Using fs As New FileStream(path, FileMode.Create, FileAccess.ReadWrite)
                barcodeBitmap.Save(memory, ImageFormat.Jpeg)
                Dim bytes As Byte() = memory.ToArray()
                fs.Write(bytes, 0, bytes.Length)
                fs.Close()
            End Using
            memory.Close()
        End Using

Reading the qrcode image :

Sub ReadQRCode()
        Dim reader = New BarcodeReader()
        Dim filename As String = Path.Combine(Request.MapPath("~/qrCodeImages/"), strFileName & ".jpg")
        ' Detect and decode the barcode inside the bitmap
        Dim result = reader.Decode(New Bitmap(filename))
        If result IsNot Nothing Then
            qrData.Visible = True
            qrData.Text = "QR Code: " + result.Text
        End If

    End Sub

Error trying to update QRCode after it has been read by Sub ReadQRCode

Answer 1

You have to dispose the bitmap instance which is created for the decoding process. It is a common problem that the Bitmap class holds the file in a locked state until it is disposed or collected by the GC. Try the following code snippet.

Sub ReadQRCode()
    Dim reader = New BarcodeReader()
    Dim filename As String = Path.Combine(Request.MapPath("~/qrCodeImages/"), strFileName & ".jpg")
    ' Detect and decode the barcode inside the bitmap
    Using bitmap As New Bitmap(filename)
        Dim result = reader.Decode(bitmap)
        If result IsNot Nothing Then
            qrData.Visible = True
            qrData.Text = "QR Code: " + result.Text
        End If
    End Using

End Sub

Perhaps you should add using blocks in the method GenerateCode, too.