如何避免 TStringList.SaveToFile 覆盖我以前的更改？

Question

I'm trying to write my TStringList into a TXT file ( mydbtxt.txt ).

I have two source files, the MainForm and a Frame. In my MainForm, there is a TabControl and a Button, where I can dynamically add more tabs. When tabs are added, the Frame will be the Parent of the new tabs.

When I add a new tab and fill up some data into it, my second tab will always overwrite my first tab. Please help, the latest keeps on overwriting my previous record.

Please refer to my image:

procedure TForm1.bSaveClick(Sender: TObject);
var
  strList: TStringList;
  i:integer;
begin
  strList := TStringList.Create;
  try
    for i := 0 to TabControl1.TabCount - 1 do
    begin
      strList.Delimiter := ' ';
      strList.QuoteChar := ',';
      strList.Add('PlanName,SavingAccount,InitialCapital,TopUp,Every,RemindOn,CashOutBy,Percentage,TotalInitialCapital' +#13#10
                              + profileFrame.plan_title.Text +','
                              + profileFrame.savingAccount_edit.Text +','
                              + profileFrame.initialCapital_edit.Text +','
                              + profileFrame.topUp_edit.Text +','
                              + profileFrame.every_comboBox.Selected.Text +','
                              + profileFrame.remindOn_comboBox.Selected.Text +','
                              + profileFrame.cashOutBy_comboBox.Selected.Text +','
                              + profileFrame.percentage_edit.Text +','
                              + profileFrame.initialCapital_edit.Text);
    end;
    strList.SaveToFile(TPath.GetDocumentsPath + TPath.PathSeparator + 'mydbtxt.txt');

  finally
    strList.Free;
  end;

end;

This is how I create my Frame, and how I add my Frame into the TabControl:

procedure TForm1.AddNewTab;
begin
  profileFrame := TProfileFrame.Create(Self);

  //TabItem
  TabItem := TabControl1.Add();
  inc(tab_name_Count);
  tabItem.Text := tab_name_Count.ToString;
  //
  profileFrame.Parent := tabItem;

end;

Answer 1

You have a single profileFrame variable that you are re-assigning each time AddNewTab() is called. In bSaveClick() , you are using that same variable in a loop, so of course every line added to the TStringList is going to have the same data. Because you are not accessing the individual TProfileFrame objects that you previously created. You are accessing only the last TProfileFrame that you created.

Since each TProfileFrame object is a child of a TTabItem , you can try this instead:

procedure TForm1.bSaveClick(Sender: TObject);
var
  strList: TStringList;
  i:integer;
  TabItem: TTabItem;
  profileFrame: TProfileFrame;
begin
  strList := TStringList.Create;
  try
    for i := 0 to TabControl1.TabCount - 1 do
    begin
      TabItem := TabControl1.Tabs[i];
      profileFrame := TabItem.Children[0] as TProfileFrame;
      strList.Add('PlanName,SavingAccount,InitialCapital,TopUp,Every,RemindOn,CashOutBy,Percentage,TotalInitialCapital');
      strList.Add(profileFrame.plan_title.Text +','
                + profileFrame.savingAccount_edit.Text +','
                + profileFrame.initialCapital_edit.Text +','
                + profileFrame.topUp_edit.Text +','
                + profileFrame.every_comboBox.Selected.Text +','
                + profileFrame.remindOn_comboBox.Selected.Text +','
                + profileFrame.cashOutBy_comboBox.Selected.Text +','
                + profileFrame.percentage_edit.Text +','
                + profileFrame.initialCapital_edit.Text);
    end;
    strList.SaveToFile(TPath.Combine(TPath.GetDocumentsPath, 'mydbtxt.txt');
  finally
    strList.Free;
  end;
end;

procedure TForm1.AddNewTab;
var
  TTabItem: TTabItem;
  profileFrame: TProfileFrame;
begin
  profileFrame := TProfileFrame.Create(Self);

  //TabItem
  TabItem := TabControl1.Add();
  inc(tab_name_Count);
  tabItem.Text := tab_name_Count.ToString;
  //
  profileFrame.Parent := tabItem;

end;

---

That being said, there is no need to duplicate the column names for each record that is added to the TStringList . That will just pollute the text file and make it harder to read. Try this instead:

procedure TForm1.bSaveClick(Sender: TObject);
var
  strList: TStringList;
  i:integer;
  TabItem: TTabItem;
  profileFrame: TProfileFrame;
begin
  strList := TStringList.Create;
  try
    strList.Add('PlanName,SavingAccount,InitialCapital,TopUp,Every,RemindOn,CashOutBy,Percentage,TotalInitialCapital');
    for i := 0 to TabControl1.TabCount - 1 do
    begin
      TabItem := TabControl1.Tabs[i];
      profileFrame := TabItem.Children[0] as TProfileFrame;
      strList.Add(profileFrame.plan_title.Text +','
                + profileFrame.savingAccount_edit.Text +','
                + profileFrame.initialCapital_edit.Text +','
                + profileFrame.topUp_edit.Text +','
                + profileFrame.every_comboBox.Selected.Text +','
                + profileFrame.remindOn_comboBox.Selected.Text +','
                + profileFrame.cashOutBy_comboBox.Selected.Text +','
                + profileFrame.percentage_edit.Text +','
                + profileFrame.initialCapital_edit.Text);
    end;
    strList.SaveToFile(TPath.Combine(TPath.GetDocumentsPath, 'mydbtxt.txt');
  finally
    strList.Free;
  end;
end;

Then the file will look more like this: