erlang JSON 数据 - 如何 select 只有一个值

Question

in erlang language I receive this kids of JSON data:

{"Time":"2020-08-16T15:28:55","BME680":{"Temperature":29.8,"Humidity":55.5,"Pressure":1003.5,"Gas":422.24},"PressureUnit":"hPa","TempUnit":"C"}

or

{"Time":"2020-08-16T11:39:49","SI7021":{"Temperature":32.4,"Humidity":99.9},"TempUnit":"C"}

I need to select only one value per each JSON data for example: based on "BME680" value

{"Temperature":29.8,"Humidity":54.8,"Pressure":1005.0,"Gas":1513.60}

or based on "SI7021" value

{"Temperature":32.4,"Humidity":99.9}

How can acive this task in erlang language? If it cold be simpler I need to extract the second value of each JSON data.

Answer 1

For decode JSON format into Erlang format data like proplists or into the maps , you can try to use 3rd party library jiffy , then you can use simple pattern matching, eg:

Maps:

1> JSON = "{\"Time\":\"2020-08-17T05:32:09\",\"BME680\":{\"Temperature\":29.6,\"Humidity\":54.6,\"Pressure\":1003.9,\"Gas\":1517.91},\"PressureUnit\":\"hPa\",\"TempUnit\":\"C\"}".
2> Map = jiffy:decode(JSON,[return_maps]).
3> #{<<"BME680">> := BME680} = Map.
4> BME680.
#{<<"Gas">> => 1517.91,<<"Humidity">> => 54.6, <<"Pressure">> => 1003.9,<<"Temperature">> => 29.6}

Proplists:

1> JSON = "{\"Time\":\"2020-08-17T05:32:09\",\"BME680\":{\"Temperature\":29.6,\"Humidity\":54.6,\"Pressure\":1003.9,\"Gas\":1517.91},\"PressureUnit\":\"hPa\",\"TempUnit\":\"C\"}".
2> {Proplists} = jiffy:decode(JSON).
3> [BME680] = [V || {K, V} <- Proplists, K == <<"BME680">>].
4> BME680.
{[{<<"Temperature">>,29.6},{<<"Humidity">>,54.6},{<<"Pressure">>,1003.9},{<<"Gas">>,1517.91}]}

Answer 2

You can use 2 modules from mochiweb project:

1. https://github.com/mochi/mochiweb/blob/master/src/mochijson2.erl
2. https://raw.githubusercontent.com/mochi/mochiweb/master/src/mochinum.erl

Put them in some folder (fe test) and run erl shell and compile this files:

alexei@MacBook-Pro test % erl
Erlang/OTP 23 [erts-11.0] [source] [64-bit] [smp:8:8] [ds:8:8:10] [async-threads:1] [hipe] [dtrace]

Eshell V11.0  (abort with ^G)
1> c("mochijson2.erl").
{ok,mochijson2}

2> c("mochinum.erl").
{ok,mochinum}

Decode json-as-text to json-as-erlang-term:

3> Body = "{\"Time\":\"2020-08-16T15:28:55\",\"BME680\":{\"Temperature\":29.8,\"Humidity\":55.5,\"Pressure\":1003.5,\"Gas\":422.24},\"PressureUnit\":\"hPa\",\"TempUnit\":\"C\"}".
"{\"Time\":\"2020-08-16T15:28:55\",\"BME680\":{\"Temperature\":29.8,\"Humidity\":55.5,\"Pressure\":1003.5,\"Gas\":422.24},\"PressureUnit\":\"hPa\",\"TempUnit\":\"C\"}"

4> {struct, Map} = mochijson2:decode(Body).
{struct,[{<<"Time">>,<<"2020-08-16T15:28:55">>},
         {<<"BME680">>,
          {struct,[{<<"Temperature">>,29.8},
                   {<<"Humidity">>,55.5},
                   {<<"Pressure">>,1003.5},
                   {<<"Gas">>,422.24}]}},
         {<<"PressureUnit">>,<<"hPa">>},
         {<<"TempUnit">>,<<"C">>}]}

Retrive the items you need:

5> {struct, Obj1} = proplists:get_value(<<"BME680">>, Map).
{struct,[{<<"Temperature">>,29.8},
         {<<"Humidity">>,55.5},
         {<<"Pressure">>,1003.5},
         {<<"Gas">>,422.24}]}

6> Item1 = proplists:lookup(<<"Temperature">>, Obj1).  
{<<"Temperature">>,29.8}

7> Item2 = proplists:lookup(<<"Humidity">>, Obj1).   
{<<"Humidity">>,55.5}

And encode erlang term to text:

8> List = [Item1, Item2].
[{<<"Temperature">>,29.8},{<<"Humidity">>,55.5}]

9> iolist_to_binary(mochijson2:encode({struct, List})).
<<"{\"Temperature\":29.8,\"Humidity\":55.5}">>

There is a very short documentation for mochijson2, but it is easy to learn just practice in shell.

Answer 3

You need to familiarize yourself with rebar3 , which is erlang's package manager. Then, you can use a package like jsx , which will allow you to convert between binary types and maps. First, you will need to convert whatever it is that you call "JSON" to a binary type, perhaps using tuple_to_list() then list_to_binary() , then you can use the jsx package to convert the binary to a map, which will enable you to extract the target value from the map.

Here's an example:

my.erl:

json_to_map(Bin) ->
    jsx:decode(
      %%<<"{\"data\": [1, 2, 3]}">>,
      Bin,
      [return_maps]
    ).

In the shell:

~/erlang_programs/myapp$ rebar3 compile
===> Verifying dependencies...
===> Compiling myapp
src/my.erl:2: Warning: export_all flag enabled - all functions will be exported

~/erlang_programs/myapp$ rebar3 shell
===> Verifying dependencies...
===> Compiling myapp
Erlang/OTP 20 [erts-9.3] [source] [64-bit] [smp:4:4] [ds:4:4:10] [async-threads:1] [hipe] [kernel-poll:false]

Eshell V9.3  (abort with ^G)

1> Bin1 = <<"{\"A\": 100, \"B\":{\"x\": 4,\"y\": [1,2,3]}}">>.
<<"{\"A\": 100, \"B\":{\"x\": 4,\"y\": [1,2,3]}}">>

2> Bin2 = <<"{\"A\":200, \"C\":{\"a\": 6, \"b\": [3,4,5]}}">>.
<<"{\"A\":200, \"C\":{\"a\": 6, \"b\": [3,4,5]}}">>

3> M1 = my:json_to_map(Bin1).                                 
#{<<"A">> => 100,
  <<"B">> => #{<<"x">> => 4,<<"y">> => [1,2,3]}}

4> M2 = my:json_to_map(Bin2).                                 
#{<<"A">> => 200,
  <<"C">> => #{<<"a">> => 6,<<"b">> => [3,4,5]}}


5> [V1] = maps:values( maps:without([<<"A">>], M1)).
[#{<<"x">> => 4,<<"y">> => [1,2,3]}]

6> V1.
#{<<"x">> => 4,<<"y">> => [1,2,3]}

7> [V2] = maps:values( maps:without([<<"A">>], M2)).
[#{<<"a">> => 6,<<"b">> => [3,4,5]}]

8> V2.
#{<<"a">> => 6,<<"b">> => [3,4,5]}

9> 

Answer 4

Hi following your advice is it correct my below code if "Body" is equal to:

    "{\"Time\":\"2020-08-17T05:32:09\",\"BME680\":{\"Temperature\":29.6,\"Humidity\":54.6,\"Pressure\":1003.9,\"Gas\":1517.91},\"PressureUnit\":\"hPa\",\"TempUnit\":\"C\"}"

my code

     ....
     eBody = jiffy:decode(<<Body>>),
     Map = #eBody,
     #{"BME680" := BME680} = Map,
     newbody = jiffy:encode(BME680),
     HTTPOptions = [],
     Options = [],
     R = httpc:request(Method, {URL, Header, Type, newbody},HTTPOptions, Options),
     ....

I'm newbie in erlang.