使用 awk 或 sed 将日期格式更改为每行多列中的已修改 ISO 日期

Question

Input file

xyz|name1|address1|19600221|M|country1|20200129|etc1
xyz|name2|address2|19610321|M|country2|20200118|etc1
xyz|name3|address3|19520217|M|country3||etc1
xyz|name4|address4|19611111|M|country4||etc1

expected output

xyz|name1|address1|1960-02-21|M|country1|2020-01-29|etc1
xyz|name2|address2|1961-03-21|M|country2|2020-01-18|etc1
xyz|name3|address3|1952-02-17|M|country3||etc1
xyz|name4|address4|1961-11-11|M|country4||etc1

Code that I used

awk -F"|" '{OFS="|";$4=strftime("%Y-%m-%d", $4); print$0}' input.txt

and redirect the output to new file and ran the same for the 7th column but the result is not as expected and I got the below

 xyz|name1|address1|1960-02-21|M|country1|1970-08-22|etc1
    xyz|name2|address2|1961-03-21|M|country2|1970-08-22|etc1
    xyz|name3|address3|1952-02-17|M|country3|1970-01-01|etc1
    xyz|name4|address4|1961-11-11|M|country4|1970-01-01|etc1

I couldn't understand why the column 7 output is different? Any advise on what is wrong here?

Answer 1

Could you please try following. Written and tested with shown samples in GNU awk .

awk '
BEGIN{
  FS=OFS="|"
}
{
  $7=($7!=""?substr($7,1,4)"-"substr($7,5,2)"-"substr($7,7):"")
}
1' Input_file

Explanation: Adding detailed explanation for above.

awk '                                         ##Starting awk program from here.
BEGIN{                                        ##Starting BEGIN section from here.
  FS=OFS="|"                                  ##Starting field separator and output field separator as | here.
}
{
  $7=($7!=""?substr($7,1,4)"-"substr($7,5,2)"-"substr($7,7):"")  ##Checking condition if 7th field is NOT NULL then using sub string to make them into the date exact format.
}
1                                             ##1 will print current edited/non-edited line here.
' Input_file                                  ##Mentioning Input_file name here.

NOTE: In case you have one or multiple columns which have dates and you want to change them to yyyy-mm-dd format etc then you could use a for loop like for (i=1;i<=NF;i++){if($i~/^[0-9]{8}$/){substr(..code above)...}

Answer 2

You could use sed for this:

$ sed -E 's/([0-9]{4})([0-9]{2})([0-9]{2})/\1-\2\-\3/g' input.txt
xyz|name1|address1|1960-02-21|M|country1|2020-01-29|etc1
xyz|name2|address2|1961-03-21|M|country2|2020-01-18|etc1
xyz|name3|address3|1952-02-17|M|country3||etc1
xyz|name4|address4|1961-11-11|M|country4||etc1

Answer 3

This is not an answer, but an extended comment.

@thanasisp's comment is on the mark. @RavinderSingh13's answer shows how to split apart and then join the date pieces into the desired format. If you want to use the time functions you still need to do that:

# reformatdate.awk

BEGIN {FS = OFS = "|"}

function formatDate(d,    t) {
  t = mktime(substr(d,1,4) " " substr(d,5,2) " " substr(d,7,2) " 0 0 0")
  return strftime("%Y-%m-%d", t)
}

{
  $4 = formatDate($4)
  if ($7) $7 = formatDate($7)
  print
}

Then

$ gawk -f reformatdate.awk input.txt
xyz|name1|address1|1960-02-21|M|country1|2020-01-29|etc1
xyz|name2|address2|1961-03-21|M|country2|2020-01-18|etc1
xyz|name3|address3|1952-02-17|M|country3||etc1
xyz|name4|address4|1961-11-11|M|country4||etc1