我需要在 SAS 中使用 if 语句创建变量吗？

Question

I need to write a code in SAS in order to substitute Access. There's one part of this code that I don't know how to do it due to the difference between Access/SQL and SAS using "if".

While in Access the command "if" doesn't need to create a new variable, in SAS we have to create it.

In Access, the code is something like this:

(IIf(date2 > par_final, par_final, date2) - 
IIf(date1 > par_initial, par_initial, date1))/365 as exposure

All the variables are in date format. When I write this in SAS code, I have to create a new variable. For example:

If date2 > par_final then 
        Field1 = par_final; Else Field1 = date2;

However, I want to create Just the exposure. I don't need to create any other variables.

How can I write this in SAS code?

I thought firstly create the first variable using the if condition and also the Second variable using if after minus. Then I make (field1 - field2)/365 to create exposure and drop field1 and field2.

Could anyone give me a better suggestion? Are there ways to do it without creating those variables?

Thanks in advance.

Answer 1

One of the divergences of MS Access' SQL dialect from standard SQL is IIF function (not to be confused with IF operator) which most database dialects use the CASE statement.

(IIf(date2 > par_final, par_final, date2) - 
 IIf(date1 > par_initial, par_initial, date1))/365 as exposure

Therefore, above can be translated with CASE expressions and should run in any compliant ANSI-92 SQL compiler including SAS's proc sql :

(CASE WHEN date2 > par_final   THEN par_final   ELSE date2 END - 
 CASE WHEN date1 > par_initial THEN par_initial ELSE date1 END) / 365 AS exposure

Answer 2

SAS has conditional logic functions IFC and IFN that return respectively a character or numeric value based on a logical evaluation. SAS date values are serial integers from epoch 01-JAN-1960 so you can continue to use subtraction to compute number of days of exposure.

Try replacing

(IIf(date2 > par_final, par_final, date2) - 
IIf(date1 > par_initial, par_initial, date1))/365 as exposure

with

( IFN(date2 > par_final, par_final, date2) 
  - 
  IFN(date1 > par_initial, par_initial, date1)
) / 365 as exposure label="Years of exposure"

Examples

data have;
input ini d1 d2 fin;
datalines;
1 2 3 4
2 1 3 4
1 2 4 3
2 1 4 3
;


* Expression in SQL;

proc sql;
  create table foo as 
  select
    ( ifn ( d2 > fin, fin, d2 )
      - 
      ifn ( d1 > ini, ini, d1 )
    )
  as diff label = 'Difference of IFNs'
  from have
  ;
quit;

* Expression in DATA Step;

data foo_also;
  set have;

  diff = ( ifn ( d2 > fin, fin, d2 )
           - 
           ifn ( d1 > ini, ini, d1 )
         );

  attrib diff label='Difference of IFNs';
run;

Also

Try using function MIN instead of IFN

   exposure = (min(d2,fin) - min(d1,ini)) / 365;