引用动态工作簿名称 - VBA

Question

I have created a workbook ("Control Panel.xlsm") for a work college to use as a storing place for all our macros we use in our day to day tasks. She is not VBA literate. One of the macros, (see code below) organizes another workbook so that it add a descriptive column at the end of a table.

    Dim lr As Long
    lr = Cells.Find("*", Cells(1, 1), xlFormulas, xlPart, xlByRows, xlPrevious, False).Row
    Dim tbl As ListObject
    Dim wbNames As Variant, wb As Workbook, w As Workbook, El As Variant, boolFound As Boolean
    wbNames = Split("January,February,March,April,May,June,July, August, September, October,November,December")
    For Each w In Workbooks
        For Each El In wbNames
            If w.Name = "Docs_Tracker_" & El & " 2020.xlsm" Then
                Set wb = w: boolFound = True: Exit For
            End If
        Next
      Next
    
    '1. Column AB - Descriptive Field - Client Name - Manager Name - Research Deliverable
If wb Is Nothing Then Stop
    Set tbl = wb.Worksheets(1).ListObjects("Table_owssvr")
    With tbl
            .ListColumns.Add.Name = "Client Name - Manager Name - Research Deliverable"
    End With
        wb.Activate
        Range("AB2:AB" & lr).FormulaR1C1 = "=CONCATENATE(RC[-22],"" - "",RC[-26],"" - "",RC[-15])"

What I would like to do is reference the workbook ("Docs_Tracker_April 2020.xlsm") so that the code still works even as the workbook reference name changes (Docs_Tracker_May 2020, Docs_Tracker_June 2020 etc)

I have tried the ActiveWorkbook, workbook Indexing method however they can have bugging issues, and isn't as foolproof with someone who isn't as familiar as VBA as my work college is.

If someone could teach me this I will apply it to all my macros they all have a similar issue. Thank you.

Answer 1

Try the next way, please. In case of more such workbooks open in the same time, it will choose the first one of the array:

Sub takeTheMonthsNamedWB()
  Dim wbNames As Variant, wb As Workbook, w As Workbook, El As Variant, boolFound As Boolean
  wbNames = Split("January,February,March,April,May,June,July", ",") 'and so on...
  For Each w In Workbooks
    For Each El In wbNames
        If w.Name = "Docs_Tracker_" & El & " 2020.xlsm" Then
            Set wb = w: boolFound = True: Exit For
        End If
    Next
    If boolFound Then Exit For 'in order to stop iteration if a lot of workbooks are open
  Next
End Sub

Edited:

Try the next testing code, please. Does it return the correct workbook name?

Sub testTheMonthsNamedWB()
  Dim wbNames As Variant, w As Workbook, El As Variant, boolFound As Boolean
  wbNames = Split("January,February,March,April,May,June,July", ",") 'and so on...
    For Each El In wbNames
        Debug.Print "Docs_Tracker_" & El & " 2020.xlsm"
    Next
End Sub

Answer 2

only two workbooks will be open ("control panel.xlsm" and "Docs tracker depending on the month"

If you would like to refer to the workbook which name depends on current month, you can use something like this:

Dim sWbkName As String, wbk As Workbook
sWbkName = "Docs_Tracker_" & Format(Date, "MMMM yyyy") & ".xlsm"
On Error Resume Next
Set wbk = Application.Workbooks(sWbkName)
If wbk Is Nothing Then
    MsgBox "Can't find '" & sWbkName & "'!!!" & vbCr & vbCr & _
        "Please, open it.", vbExclamation, "Error."
    Exit Sub
End If