如何使用 VBA 从 XLS 创建操作过的 CSV 文件

Question

I have an excel file that I need to convert into a CSV. This part is fine, I wrote this code to do so:

Private Sub createCSV()
Dim path As String
Dim ws As Excel.Worksheet

path = "\\networkshare\mydir"

For Each ws In Application.ActiveWorkbook.Worksheets
    ActiveSheet.Range("1:2").EntireRow.Delete       'Delete the first two rows
    ws.SaveAs path & ws.Name, xlCSV
Next


End Sub

However,

I need to only save specific columns to CSV in a certain order.

Column A,B of excel worksheet to Column D,E of CSV and Column C,D of worksheet as column A,B of CSV,etc

Is there a way to do this?

Answer 1

Try the next code, please (take care of the last "" in path string):

Private Sub createCSV()
 Dim ws As Worksheet, path As String, arr As Variant, lastRow As Long

 path = "\\networkshare\mydir\" 'take care of the last "\"!!!

 For Each ws In ActiveWorkbook.Worksheets
    ws.Range("1:2").EntireRow.Delete                   'Delete the first two rows
    lastRow = ws.Range("A" & rows.count).End(xlUp).row 'last row of the sheet
    arr = ws.Range("A1:D" & lastRow).Value             'put the range in an array
    'switch the array columns
    arr = Application.Index(arr, Evaluate("row(1:" & UBound(arr) & ")"), Array(3, 4, 1, 2))
    ws.Range("A1").Resize(UBound(arr), UBound(arr, 2)).Value = arr 'drop the adapted array back in the sheet
    ws.SaveAs path & ws.Name & ".csv", xlCSV          'save the sheet as csv
 Next
End Sub