从另一个工作表复制等于单元格值的单元格

Question

I have 3 worksheets: Worksheet A, B, and C.

Worksheet B has cells that are pulling information from Worksheet A and placing in specific visual format.

I then alter the color of the cells on Worksheet B (the same cells whose value is equal to Worksheet A) and trying to copy both values and colors to Worksheet 3 in one column.

Sub copycellcolor1()
Dim rField As Range
Dim idCell As Range
Dim r1WS As Worksheet
Dim rrWS As Worksheet

Set r1WS = Worksheets("RACK 1")
Set rField = r1WS.Range("C6:N13")
Set rrWS = Worksheets("Reruns To Pull")

For Each idCell In rField

    If idCell.Interior.color = RGB(204, 204, 255) Then
        idCell.Copy rrWS.Range("A1").Offset(rrWS.Rows.Count - 1, 0).End(xlUp).Offset(1, 0)
    End If
    
Next idCell

rrWS.Columns.AutoFit

End Sub

I'm getting the correct color on Worksheet 3, but the value is #REF! because the actual value of the cell is referring to Worksheet A.

Can someone please explain what I'm doing wrong?

Answer 1

PasteSpecial

You're using the wrong way to copy/paste . Try the following:

    If idCell.Interior.Color = RGB(204, 204, 255) Then
        With rrWS.Range("A1").Offset(rrWS.Rows.Count - 1, 0).End(xlUp).Offset(1, 0)
            idCell.Copy
            ' Paste values.
            .PasteSpecial xlPasteValues
            ' Paste formats.
            .PasteSpecial xlPasteFormats
            Application.CutCopyMode = False
        End With
    End If
    
    ' This is a little bit ridiculous, but it works.
    If idCell.Interior.Color = RGB(204, 204, 255) Then
        With rrWS.Range("A1").Offset(rrWS.Rows.Count - 1, 0).End(xlUp).Offset(1, 0)
            ' Paste values.
            .Value = idCell.Value
            ' Paste formats.
            idCell.Copy
            .PasteSpecial xlPasteFormats
            Application.CutCopyMode = False
        End With
    End If