如何从windows批处理文件中获取当前目录相关路径

Question

I want to know how can we get current directory of batch file and parent directories of batch file. It will be easy to explain by example. Lets assume my batch file location D:\\Ashish\\Gupta\\abc\\xyz.bat How to get below locations from xyz.bat

1. D:\\Ashish\\Gupta\\abc ->
2. D:\\Ashish\\Gupta ->
3. D:\\Ashish ->
4. D: ->

I tried to search on internet and get couple of answers but still confused.

Answer 1

you can use PUSHD .. with a for /L loop and If conditional statements until you reach the root directory, like so:

@Echo off & CD "%~dp0"
 Set "Path[0]=%~dp0"
  Setlocal EnableDelayedExpansion
  PUSHD ..
  For /L %%i in (1 1 20)Do (
    If /I not "!CD!" == "!LastDir!" (
    Set "Path[%%i]=!CD!"
    Set "Root{i}=%%i"
    Set "LastDir=!Path[%%i]!"
    PUSHD ..
   )
  )
 Set Path[
 Set Root{
 For /L %%i in (0 1 %Root{i}%) Do POPD
 ECHO %CD%
 Endlocal

The above creates a zero indexed array of the parent folders right back to the root drive. the 20 value used in the for /L loop iterations is a fairly arbitrary number - I can't see many situations where you'll be nesting that many subfolders, however if for some reason you have deeply nested subfolders, you may need to increase the number of iterations.

Answer 2

That is very simple to achieve:

@echo off
setlocal EnableExtensions DisableDelayedExpansion
set "FilePath=%~dp0"
:ParsePath
for %%I in ("%FilePath%.") do (
    echo %%~fI
    set "FilePath=%%~dpI"
    if not "%%~dI\" == "%%~dpI" if not "%%~dpI" == "%%~fI" goto ParsePath
    if not "%%~dpI" == "%FilePath%" echo %%~dI\
)
endlocal
pause

The batch file defines first the execution environment with the first two command lines.

Then it assigns the full path of the batch file always ending with a backslash to the environment variable FilePath .

The command for is used to get the string left to last backslash in environment variable FilePath (drive and path) and the string right to last backslash in environment variable FilePath (current folder name).

The . is appended to string assigned to FilePath to force command for to access the file system to get the current file path without a backslash at end. The dot means current directory. So on first iteration of the for loop D:\\Ashish\\Gupta\\abc\\ is extended to D:\\Ashish\\Gupta\\abc\\. and for that reason %%~fI expands to D:\\Ashish\\Gupta\\abc while %%~dpI expands to D:\\Ashish\\Gupta\\ for the next loop run.

%%~fI and %%~dpI would expand on first loop run both to D:\\Ashish\\Gupta\\abc\\ if just "%FilePath%" without . would be used because of in this case the file/folder string defines already an absolute path not containing anymore any relative part and so for would not access the file system to determine full file/folder name and full path of file/folder.

It is possible to use command for to split up a file/folder string of a file or folder which does not exist at all. There is if exist to check if a file/folder exists. The command for is not designed for file/folder existence checks. There are lots of uses cases on which for is used to split up a full qualified file name into file path and file name + extension without file already existing yet.

One directory name after the other is removed from FilePath until there is left only either drive letter + colon + backslash like C:\\ or \\\\ComputerName\\ in case of batch file is stored on a network resource accessed using UNC path.

The condition if not "%%~dI\\" == "%%~dpI" is not true on root directory of the drive is the remaining file path.

The condition if not "%%~dpI" == "%%~fI" is not true on \\\\ComputerName\\ is the remaining file path.

So the top level is reached if one of these two conditions is not true anymore and for that reason there is no more goto ParsePath executed to parse the remaining file path once more. There is instead output the root directory path of the drive if the batch file was not called using a UNC path and the batch file is not stored in root directory of a drive.

The batch file outputs on running D:\\Ashish\\Gupta\\abc\\ParsePath.bat :

D:\Ashish\Gupta\abc
D:\Ashish\Gupta
D:\Ashish
D:\

The batch file outputs on running D:\\ParsePath.bat :

D:\

The batch file outputs on running \\\\GuptaMachine\\D$\\Ashish\\Gupta\\abc\\ParsePath.bat :

\\GuptaMachine\D$\Ashish\Gupta\abc
\\GuptaMachine\D$\Ashish\Gupta
\\GuptaMachine\D$\Ashish\
\\GuptaMachine\D$
\\GuptaMachine\

See also the output of following command lines in batch file:

for %%I in ("%~dp0.") do (
    echo Batch file folder name: %%~nxI
    echo Batch file folder path: %%~fI
)

I recommend to read also the Microsoft documentation about Naming Files, Paths, and Namespaces as it is also possible to use .. or ..\\.. with %~dp0 to get the folder path of one of the parent folders on being sure there are parent folders as the batch file is never stored in root folder of a drive.

For understanding the used commands and how they work, open a command prompt window, execute there the following commands, and read entirely all help pages displayed for each command very carefully.

• call /? ... explains how to reference batch file arguments like argument 0 which is the batch file itself.
• echo /?
• endlocal /?
• for /?
• if /?
• pause /?
• set /?
• setlocal /?