PL/SQL：当我尝试调用 sql%bulk_rowcount(j) 时，我得到“必须声明标识符 j”；

Question

My code:

create table dep_emp_ast(
cod_dep number(3),
cod_ang number(3));

declare
type tab_imb is table of dept_ast.department_id%type;
type ang is table of emp_ast.employee_id%type;
v_ang ang:=ang();
t tab_imb:=tab_imb();
begin
select department_id
bulk collect into t
from dept_ast;

for i in 1..t.count loop
select employee_id bulk collect into v_ang
from emp_ast
where department_id=t(i);

forall j in 1..v_ang.count
insert into dep_emp_ast
values(t(i), v_ang(j));
dbms_output.put_line( sql%bulk_rowcount(j));
v_ang.delete;
end loop;
end;
/

I get "Identifier 'j' must be declared'" when I try to call sql%bulk_rowcount(j); I know I can use sql%bulk_rowcount(index) in for or forall loops.

Answer 1

Here's a working version.

I renamed some variables to be easier to understand (for me at least), and I added some more dbms_output messages to show what it's doing more clearly.

declare
    type tab_dept is table of dept_ast.department_id%type;
    type tab_emp  is table of emp_ast.employee_id%type;
    employees_t    tab_emp := tab_emp();
    departments_t  tab_dept := tab_dept();
begin
    select department_id bulk collect into departments_t
    from   dept_ast;

    dbms_output.put_line(departments_t.count || ' departments added to departments_t');

    for i in 1 .. departments_t.count loop
        select employee_id bulk collect into employees_t
        from   emp_ast where department_id = departments_t(i);

        dbms_output.put_line(employees_t.count || ' employees added to employees_t for department_id '||departments_t(i));

        forall j in 1 .. employees_t.count
        insert into dep_emp_ast
        values
        ( departments_t(i)
        , employees_t(j) );

        for k in 1 .. employees_t.count loop
            dbms_output.put_line('sql%bulk_rowcount('||k||') = '|| sql%bulk_rowcount(k));
        end loop;

        dbms_output.put_line('sql%rowcount = ' ||sql%rowcount);
        employees_t.delete;
    end loop;
end;

Output:

3 departments added to departments_t
2 employees added to employees_t for department_id 1
sql%bulk_rowcount(1) = 1
sql%bulk_rowcount(2) = 1
sql%rowcount = 2
2 employees added to employees_t for department_id 2
sql%bulk_rowcount(1) = 1
sql%bulk_rowcount(2) = 1
sql%rowcount = 2
2 employees added to employees_t for department_id 3
sql%bulk_rowcount(1) = 1
sql%bulk_rowcount(2) = 1
sql%rowcount = 2

Test setup:

create table dep_emp_ast(
cod_dep number(3),
cod_ang number(3));

create table dept_ast
( department_id number );

create table emp_ast
( employee_id number 
, department_id number );

delete dept_ast;
delete emp_ast;

insert all
    into dept_ast values (1)
    into dept_ast values (2)
    into dept_ast values (3)
    into emp_ast (department_id, employee_id) values (1, 10)
    into emp_ast (department_id, employee_id) values (1, 20)
    into emp_ast (department_id, employee_id) values (2, 30)
    into emp_ast (department_id, employee_id) values (2, 40)
    into emp_ast (department_id, employee_id) values (3, 50)
    into emp_ast (department_id, employee_id) values (3, 60)
select * from dual;

Answer 2

@WilliamRobertson is correct in his comment that "you haven't declared j anywhere" and I take his word that it is a working version. But neither actually explains why you get the error. Your code actually shows 2 misconceptions.
First the initialization (for lack of a better work) of FOR and FORALL is

FOR <index> IN <lower bound> .. <upperbound> Loop ... END LOOP; 
FORALL <index> IN <lower bound> .. <upperbound> DML statement;

In both cases the variable is created for the duration of the statement only . Thus when the loop or the DML statement terminates the variable no longer exists. Thus when you used the variable j after the insert ended it no longer existed. Even if you do declare a variable with the same name the scoping rules cause them to be different variables (see example here ).
You have another issue as well. SQL%bulk_rowcount contains as entry for each row row processed, but since the index variable of the forall no longer exists you need a FOR loop to iterate them. So, after the forall:

for j in 1..v_ang.count
loop
    dbms_output.put_line( ' Rows for ' || v_ang(j) || ':' || SQL%bulk_rowcount(j));
end loop;

But assuming v_ang contains the PK for employee table (seems likely) that will just five you a list of 1. Perhaps you actually want SQL%Rowcount. That gives you the total number of rows processed.

I hope this helps you to understand for(all) loop index variables.