如何使用 perl 正则表达式匹配可变长度数字范围 0 到 $n？

Question

I need to match a numeric range from 0 to a number $n where $n can be any random number from 1 - 40.

For example, if $n = 16, I need to strictly match only the numeric range from 0-16.

I tried m/([0-9]|[1-3][0-9]|40)/ but that is matching all 0-40. Is there a way to use regex to match from 0 to $n?

The code snippet is attached for context.

$n = getNumber();                #getNumber() returns a random number from 1 to 40.
$answer = getAnswer();           #getAnswer() returns a user input.

#Check whether user enters an integer between 0 and $n
if ($answer =~ m/regex/){
   print("Answer is an integer within specified range!\n");
}

I know can probably do something like

if($answer >= 0 && $answer <=$n)

But I am just wondering if there is a regex way of doing it?

Answer 1

I wouldn't pull out the following trick if there's another reasonable way to solve the problem. There is, for instance, Matching Numeric Ranges with a Regular Expression .

The (?(...)true|false) construct is like a regex conditional operator, and you can use one of the regex verbs, (*FAIL) , to always fail a subpattern.

For the condition, you can use (?{...}) as the condition:

my $pattern = qr/
    \b                       # anchor somehow
    (\d++)                   # non-backtracking and greedy
    (?(?{ $1 > 42 })(*FAIL))
    /x;

my @numbers = map { int( rand(100) ) } 0 .. 10;

say "@numbers";

foreach my $n ( @numbers ) {
    next unless $n =~ $pattern;
    say "Matched $n";
    }

Here's a run:

74 69 24 15 23 26 62 18 18 43 80
Matched 24
Matched 15
Matched 23
Matched 26
Matched 18
Matched 18

This is handy when the condition is complex.

I only think about this because it's an encouraged feature in Raku (and I have several examples in Learning Perl 6 ). Here's some Raku code in the same form, and the pattern syntax is significantly different:

#!raku

my $numbers = map { 100.rand.Int }, 0 .. 20;

say $numbers;

for @$numbers -> $n {
    next unless $n ~~ / (<|w> \d+: <?{ $/ <= 42 }>) /;
    say $n
    }

The result is the same:

(67 43 31 41 89 14 52 71 48 64 5 21 6 31 44 27 39 94 78 15 39)
31
41
14
5
21
6
31
27
39
15
39

Answer 2

You can dynamically create the pattern. I've used a non-capture group (?:) here to keep the start and end of string anchors outside the list of | -ed numbers.

my $n = int rand 40;
my $answer = 42;

my $pattern = join '|', 0 .. $n;

if ($answer =~ m/^(?:$pattern)$/) {
    print "Answer is an integer within specified range";
}

Please keep in mind that for your purpose this makes little sense.