vba 循环遍历工作簿

Question

Hi to everyone i have a problem and i can't understand why this does not work, here is the problem:

i have a sub that do some stuff but before the sub begin i want to test if the workbooks needed are present in the folder they are 4 so i can do one by one but i think there are better solutions so i came up with this

**Sub test()

Dim link1, link2, link3, link4 As String
link1 = "C:\Users\Cristiano\Desktop\prove excel\loco.xlsx"
link2 = "C:\Users\Cristiano\Desktop\prove excel\668.xlsx"
link3 = "C:\Users\Cristiano\Desktop\prove excel\mezzi leggeri.xlsx"
link4 = "C:\Users\Cristiano\Desktop\prove excel\blocci vetture.xlsx"

For r = 1 To 4
   If Dir(link & r) = "" Then
    MsgBox "file not found in the path"&" "& link & r
    End If
Next r

end sub**

but it does not work, if it was possible i would like to put just the missing file in a unique msgbox

what i am doing wrong?

thanks in advance

Answer 1

• Use Option Explicit which will force you to declare all variables ( r ).

• When declaring variables in one line, every variable has to have an As :

   Dim link1 As String, link2 As String, link3 As String, link4 As String

• You can write the file paths to an array .

The Code

Option Explicit

Sub test()

    Dim Paths(1 To 4) As String
    Paths(1) = "C:\Users\Cristiano\Desktop\prove excel\loco.xlsx"
    Paths(2) = "C:\Users\Cristiano\Desktop\prove excel\668.xlsx"
    Paths(3) = "C:\Users\Cristiano\Desktop\prove excel\mezzi leggeri.xlsx"
    Paths(4) = "C:\Users\Cristiano\Desktop\prove excel\blocci vetture.xlsx"
    
    Dim r As Long
    For r = 1 To 4
        If Dir(Paths(r)) = "" Then
            MsgBox "File '" & Paths(r) & "' not found."
        End If
    Next r

End Sub

Here's another one:

Sub test2()
    Dim mat(1 To 4) As String
    mat(1) = "C:\Users\Cristiano\Desktop\prove excel\loco.xlsx"
    mat(2) = "C:\Users\Cristiano\Desktop\prove excel\668.xlsx"
    mat(3) = "C:\Users\Cristiano\Desktop\prove excel\mezzi leggeri.xlsx"
    mat(4) = "C:\Users\Cristiano\Desktop\prove excel\blocchi vetture.xlsx"
    Dim fso As Object
    Set fso = CreateObject("Scripting.FileSystemObject")
    Dim r As Long
    Dim msg As Object
    Set msg = CreateObject("System.Collections.ArrayList")
    For r = 1 To 4
        If Not fso.FileExists(mat(r)) Then
            msg.Add fso.GetFileName(mat(r))
        End If
    Next r
    msg.Sort
    Dim arr As Variant
    arr = msg.ToArray
    MsgBox Join(arr, vbLf)
End Sub