F# class 这两个同类型的对象为什么不相等呢？

Question

Can someone explain to me why these two objects are not equal, and what is the solution for handling such concerns?

[<AllowNullLiteralAttribute>]
type Duration (id, startDate, endDate) =
    
    member val DbId : string = id with get,set
    member val StartDate : Nullable<DateTime> = startDate with get,set
    member val EndDate : Nullable<DateTime> = endDate with get,set

    new () =
        Duration(null, System.Nullable(), System.Nullable())

[<AllowNullLiteralAttribute>]
type ProductMedium (mediumType, fileLink, duration) =
    member val MediumType : string = mediumType with get,set
    member val FileLink : string = fileLink with get,set
    member val Duration : Duration = duration with get,set

    new () =
        ProductMedium (null, null, null)

let medium1 = new ProductMedium("Type1", null, null)
let medium2 = new ProductMedium("Type1", null, null)

medium1 = medium2 // returns false

Answer 1

That's just how equality in .NET works: by default, unless you implement comparison methods yourself, equality is "by reference" - that is, every object is equal only to itself and to nothing else.

For many standard library types, such as strings, comparison methods are, in fact, implemented. That's why equal strings are equal, even if they're not the same object. But for types that you roll yourself you have to implement the comparison methods as you see fit.

For what you're trying to do here, the method you want is Equals . This is a virtual method on the System.Object type, and by default it works the way described above: every object is equal only to itself. But you can override it for your type:

type ProductMedium (mediumType, fileLink, duration) =
    member val MediumType : string = mediumType with get,set
    member val FileLink : string = fileLink with get,set
    member val Duration : string = duration with get,set

    override this.Equals(other) = 
      match other with
      | :? ProductMedium as p -> 
          this.MediumType = p.MediumType && this.FileLink = p.FileLink && this.Duration = p.Duration
      | _ ->
          false

Now the comparison will work the way you expect it to. But you will also get a warning asking you to implement GetHashCode as well. This is because many standard containers in the .NET library (such as Dictionary or Hashtable ) expect equal objects to also have the same hash and may not work correctly if your objects don't do this. I will leave the implementation of GetHashCode as an exercise. See documentation for more info.

---

But since you're using F#, you actually have a better option available to you: don't use regular .NET classes, use F# records instead:

type ProductMedium = { MediumType : string; FileLink : string; Duration : string }

let medium1 = { MediumType = "Type1"; FileLink = null; Duration = null }
let medium2 = { MediumType = "Type2"; FileLink = null; Duration = null }

F# records have "structural equality" (ie two records are equal when all their fields are equal) by default, implemented for you by the compiler, but they also provide other benefits, such as much shorter syntax, immutability by default, functional update syntax, pattern-matching, type inference, and more. Highly recommend.