这是 Groovy 收集关闭缩写的用法吗？

Question

I study the Groovy code which deals with JSON parsing and find the following strange code that I cannot understand:

list.groovy

def lst = [
    [name: 'Bill', age: 30],
    [name: 'Jobs', age: 40],
    [name: 'Steve', age: 50],
]

println lst
println lst.name
println lst.collect{it.name}
println lst.age
println lst.agenda

Platform: Windows 10, Groovy version: 2.5.9

C:\chenchang\study\groovy_study\closure>groovy -version
Groovy Version: 2.5.9 JVM: 1.8.0_272 Vendor: AdoptOpenJDK OS: Windows 10

The output of the Groovy script:

C:\chenchang\study\groovy_study\closure>groovy list.groovy
[[name:Bill, age:30], [name:Jobs, age:40], [name:Steve, age:50]]
[Bill, Jobs, Steve]
[Bill, Jobs, Steve]
[30, 40, 50]
[null, null, null]

I cannot understand lst.name part. It looks like lst.collect{it.name} but I cannot find any reference documentation or formal explanations. Can anyone explain what Groovy syntax it is?

---

After reviewed your comments, I update the sample code and find some new knowledge that I don't know before.

def lst = [
    [name: 'Bill', age: 30],
    [name: 'Jobs', age: 40],
    [name: 'Steve', age: 50],
    null, // I add a null value in the list
]
println lst
println lst.name
println lst.findAll{ it != null }.collect{ it.name }
println lst*.name
/* println lst.collect{ it.name } */
/* java.lang.NullPointerException: Cannot get property 'name' on null object */
println lst.collect{ it?.name }

The output of the revised Groovy script:

C:\chenchang\study\groovy_study\closure>groovy list.groovy
[[name:Bill, age:30], [name:Jobs, age:40], [name:Steve, age:50], null]
[Bill, Jobs, Steve]
[Bill, Jobs, Steve]
[Bill, Jobs, Steve, null]
[Bill, Jobs, Steve, null]

lst.name is GPath which ignores the null values. So the length of the returned new list will be less than the length of the original list if the original list contains null values. lst.name is equivalent to lst.findAll{ it.= null }.collect{ it.name } .

lst*.name is spread dot operator or Star dot operator . The length of the returned new list is equal to the length of the original list. If some values in the original list are null , the corresponding values in the new list will be null and no NullPointerException will be thrown. lst*.name is equivalent to lst.collect{ it?.name } .

Answer 1

It's the GPath notation for collections.

GPath can be used to process data such as XML, JSON and collections.

Answer 2

def lst = [] is a java.util.ArrayList

you can use println lst.getClass() to check it

ArrayList implements Iterable , Collection , ... and other interfaces

groovy could add functionality on any level of super interface or super class.

groovy gdk documentation explains additional functionality that groovy adds to java

to get list of all available methods in groovy you have to check java doc and all super classes/interfaces of groovy doc.

in case of lst.name groovy actually calls lst.getAt('name')

getAt(String key) - you can find in groovy doc Collection

and finally here is a doc about groovy collections: http://docs.groovy-lang.org/next/html/documentation/working-with-collections.html