创建 PDF 编译错误“Application: defined or object-defined error”

Question

I have a VBA userform where the user searches the database sheet for certain terms. It generates the result in a separate sheet and when the user clicks the print button it creates a PDF that includes all the data in the search result sheet.

It is giving the compile error

"Application: defined or object-defined error"

Sub CreatePDF()

    Sheet4.Select
    Range("A1:N25").Select
 

        ThisWorkbook.Sheets("SearchData").Select
        Selection.ExportAsFixedFormat _
            Type:=xlTypePDF, _
            Filename:="D:\AliBinAli\Security Visitor App\temp.pdf", _
            Quality:=xlQualityStandard, _
            Orientation:=xlLandscape, _
            IncludeDocProperties:=True, _
            IgnorePrintAreas:=False, _
            OpenAfterPublish:=True
               
       
    Sheet4.Select
    Range("A1").Select

End Sub

The highlighted line is:

Selection.ExportAsFixedFormat _ Type:=xlTypePDF, _             
  Filename:="D:\AliBinAli\Security Visitor App\temp.pdf", _             
  Quality:=xlQualityStandard, _
  Orientation:=xlLandscape, _
  IncludeDocProperties:=True, _
  IgnorePrintAreas:=False, _
  OpenAfterPublish:=True

Answer 1

Orientation

PageSetup.Orientation

Range.Orientation

There is no Orientation argument in the Worksheet.ExportAsFixedFormat method .
You could try this:

Option Explicit

Sub CreatePDF()

    With ThisWorkbook.Worksheets("SearchData")
        .PageSetup.Orientation = xlLandscape
        .ExportAsFixedFormat _
            Type:=xlTypePDF, _
            Filename:="D:\AliBinAli\Security Visitor App\temp.pdf", _
            Quality:=xlQualityStandard, _
            IncludeDocProperties:=True, _
            IgnorePrintAreas:=False, _
            OpenAfterPublish:=True
    End With
    
    With Sheet4
        .Activate
        .Range("A1").Select
    End With

End Sub

or if you wanted to print the range:

Sub CreatePDF2()
 
    With Sheet4.Range("A1:N25")
        .Worksheet.PageSetup.Orientation = xlLandscape
        .Orientation = xlHorizontal
        .ExportAsFixedFormat _
            Type:=xlTypePDF, _
            Filename:="D:\AliBinAli\Security Visitor App\temp.pdf", _
            Quality:=xlQualityStandard, _
            IncludeDocProperties:=True, _
            IgnorePrintAreas:=False, _
            OpenAfterPublish:=True
        .Worksheet.Activate
        .Cells(1).Select   
    End With

End Sub