如何对日期数据类型进行排序？

Question

I've been trying to sort dates on A1 but it sorts based on text not the value

Private Sub sortData()

Worksheets(Me.Combobox1.Value).Range("A1:F1", Range("A1:F1").End(xlDown)).Sort
 Key1:=Range("A1"), Order1:=xlAscending, Header:=xlYes
End Sub

Answer 1

As @Marcelo Scofano Diniz started to say, when you run into a problem forget about the shortcxuts and go by the book. Here is the book.

Private Sub SortByDate()
    
    Dim Ws              As Worksheet
    Dim SortRange       As Range
    
    Set Ws = Worksheets(Me.ComboBox1.Value)
    With Ws
        Set SortRange = .Range(.Cells(1, 1), .Cells(.Rows.Count, "A").End(xlUp)) _
                        .Resize(, 6)
        With .Sort.SortFields
            .Clear
            .Add2 Key:=SortRange.Cells(1), _
                  SortOn:=xlSortOnValues, _
                  Order:=xlAscending, _
                  DataOption:=xlSortNormal
        End With
        
        With .Sort
            .SetRange SortRange
            .Header = xlYes
            .MatchCase = False
            .Orientation = xlTopToBottom
            .SortMethod = xlPinYin
            .Apply
        End With
    End With
End Sub

The above code will carry out the sort you say your code won't do. If the dates are true dates they will be sorted by date. If they are fake dates they will be sorted as text. And if you have doubt about any part of the code you can see what is being done and step through it line by line.

Answer 2

Change The Range to Table of Name Tbl then Create:

Sub Table_Sort(byval FieldNo as Integer)
    Tbl.Sort.SortFields.Clear
    FieldRange(FieldNo).Select
       Tbl.Sort.SortFields.Add _
   Key:=FieldRange(FieldNo), SortOn:=xlSortOnValues, Order:= _
   xlAscending, DataOption:=xlSortNormal

   With Tbl.Sort

   .Header = xlYes
   .MatchCase = False
   .Orientation = xlTopToBottom
   .SortMethod = xlPinYin
   .Apply
   
   End With

End Sub