在 Arrayformula 中提取行

Question

I think this is a simple syntax problem. I am extracting keywords from a string. The keyword set is in a column and the source strings are in a separate column.

I want the keyword result of each string in the adjacent column using a single arrayformula type construct at the head of the result column. I'm open to QUERY, FILTER or any other type of dynamic array formula.

The real world spreadsheet has a test string column of indeterminate size ranging from zero entries to around 4000 depending on the build query. The keyword column is also dynamic and changes when the system needs to append or delete keywords. It's currently only around 60 rows. There is a limit of four results per string with no particular priority of the matching keywords and no constraint on the order in which they appear.

A keyword can be any number of words. So 'Tree' and 'Tall Tree' would be two rows. The longer keyword string always takes priority. So for example the keyword result of the string 'I have a tall tree in my garden' would be 'Tall Tree' and not 'Tree, Tall Tree'.

A short example: My keyword set (column A - and given the Named Range here of 'myWords'):

    ate
    blue
    cat
    the cat
    for
    dead
    bob
    alive

My strings to test (column B):

Bob ate the dead cat
The cat ate live bob
No cat ate live dog
Bob is dead
Bob and the cat are alive

My expected results (column C):

Bob, Ate, Dead, Cat
The Cat, Ate, Bob
Cat, Ate
Bob, Dead
Bob, The Cat, Alive

The example spreadsheet is here .

If I copy down the following formula I get my expected results.

=PROPER(TEXTJOIN(", ",TRUE,ArrayFormula(IFERROR(REGEXREPLACE($A2,REGEXREPLACE($A2,"(?i)("&TEXTJOIN("|",TRUE,myWords)&")","(.*)"),{"$1","$2","$3","$4"})))))

Good result, unwanted method:

Bob, Ate, Dead, Cat
The Cat, Ate, Bob
Cat, Ate
Bob, Dead
Bob, The Cat, Alive

If I construct an arrayformula version then I get the right result but all on the first row.

=arrayformula(PROPER(TEXTJOIN(", ",TRUE,IFERROR(REGEXREPLACE($A$2:$A$20,REGEXREPLACE($A$2:$A$20,"(?i)("&TEXTJOIN("|",TRUE,myWords)&")","(.*)"),{"$1","$2","$3","$4"})))))

Unwanted result, preferred type of method:

Bob, Ate, Dead, Cat, The Cat, Ate, Bob, Cat, Ate, Bob, Dead, Bob, The Cat, Alive

I feel the answer is going to be embarrassingly simple - but I just can't get it!

UPDATE 31/12/2020 The answer below by player0 is the perfect solution. The example spreadsheet has been updated with this answer.

Answer 1

use:

=ARRAYFORMULA(REGEXREPLACE(TRIM(FLATTEN(QUERY(TRANSPOSE(
 PROPER(IFERROR(REGEXREPLACE(B2:B14, REGEXREPLACE(B2:B14, "(?i)("&
 TEXTJOIN("|", 1, myWords)&")", "(.*)"), 
 {"$1,", "$2,", "$3,", "$4,"})))),,9^9))), ",$", ))

update:

=ARRAYFORMULA(REGEXREPLACE(TRIM(FLATTEN(QUERY(TRANSPOSE(
 PROPER(IFERROR(REGEXREPLACE(REGEXREPLACE(B2:B14, "\+", "♂"), 
 REGEXREPLACE(REGEXREPLACE(B2:B14, "\+", "♂"), "(?i)("&
 TEXTJOIN("|", 1, Answer!myWords)&")", "(.*)"), 
 {"$1,", "$2,", "$3,", "$4,"})))),,9^9))), ",$", ))