使用 VBA 在大型 Excel 表中搜索值的最佳方法是什么？

Question

I am currently working on an excel Userform to generate a report for a lot entered on a given day. The report is stored in a separate word document which contains the results of between 1 and 8 quality samples (number of samples varies by lot). The Userform is meant to load in excel, receive a lot number and date from the user, retrieve samples from that day and lot from a different sheet in the excel workbook and then copy the data into a new word doc based on a custom template. I have inserted the MsgBox method into the macro at various points for bug-squashing purposes. The data set I am using is organized by both date and lot number (in columns A and C, respectively) and the goal of the macro I am writing is to copy all rows containing a chosen date and lot number into a word document.

I have encountered a problem where the Application.Match() function is not returning the correct response when I use it to search for a particular lot number. I haven't yet found a better way to search for an exact data point in a data set, and I am also struggling to match the pDay to the date object stored in the spreadsheet.

Sub makeReport(lNum As Integer, pDay As Date, name As String)
    'Template Path: \\CORE\Miscellaneous\Quality\Sample Reports\Template\Defect Report.dotm
    'Save path for finished report: \\CORE\Miscellaneous\Quality\Sample Reports
    
    'Initialize word objects and open word
    Dim wApp As Word.Application
    Dim wDoc As Word.Document
    Dim wCell As Word.Cell
    
    MsgBox ("Word Doc Opened")
    
    Set wApp = New Word.Application
    wApp.Visible = True
    Set wDoc = wApp.Documents.Add(Template:=("\\CORE\Miscellaneous\Quality\Sample Reports\Template\Defect Report.dotm"), NewTemplate:=False, DocumentType:=0)
    
    MsgBox ("Word Objects Initialized")
    
    'Fill in lot number and date at top of report
    With wDoc
        .Application.Selection.Find.Text = "<<date>>"
        .Application.Selection.Find.Execute
        .Application.Selection = Format(pDay, "mm/dd/yyyy")
        .Application.Selection.EndOf
    
        .Application.Selection.Find.Text = "<<lot>>"
        .Application.Selection.Find.Execute
        .Application.Selection = lNum
    End With
    
    MsgBox ("Filled in pack date and lot number")
    
    'Initialize excel objects
    Dim wBook As Workbook
    Dim wFunc As WorksheetFunction
    
    Set wFunc = Application.WorksheetFunction
    Set wBook = ThisWorkbook
    
    Worksheets("Defect Table").Activate
    Application.ActiveSheet.UsedRange.Select
    
    MsgBox ("Set Active Sheet to Defect Table")
    
    'Initialize copy control variables
    Dim rowArray(7) As Integer
    Dim tBound As Integer
    Dim cRange As Range
    Dim vRange As Range
    Dim count As Integer
    Dim tHold As Variant
    Dim i As Long
    
    
    'Counter for do while loop
    count = 0
    
    'Range object containing all used cells
    Set cRange = ActiveSheet.UsedRange.Rows
    
    'First row containing desired lot number
    tHold = Application.Match(lNum, cRange, 0)
    tBound = CInt(tHold)
    
    MsgBox ("First found row: " + CStr(tBound))
    
    rowArray(0) = tBound
    
    'Range object containing all unscanned used cells
    Set vRange = cRange.Offset(tBound, 0)
    
    MsgBox ("Copy control variables initialized")
    
    'Finds and stores row numbers of desired samples
    Do While count < 7 And tBound < 3000
        'Adjusts vrange
        Set vRange = cRange.Offset(tBound, 0)
        i = CLng(count + 1)
        
        'Checks if row contains correct date, then copies row number into an array
        If (pDay = vRange.Cells(tBound, 1).Value()) Then
            rowArray(i) = tBound
            count = count + 1
        End If
        
        tBound = tBound + 1
    Loop
    
    count = 0
    
    'Prints out contents of rowArray
    Dim msg As String
    msg = "Row numbers of samples: "
    
    Do While count < 7
        msg = msg + vbCrLf + CStr(rowArray(count))
        count = count + 1
    Loop
    
    MsgBox (msg)
    
    count = 0
    
    MsgBox ("Appropriate samples found")
    
    'Copies samples over to word doc
    'Do While count < 7
    
    'Loop
    
    '---MsgBox ("Data copied to Word Doc")
    
    'Saves Document using regular name format for ease of access
    '---wDoc.SaveAs2 Filename:="\\CORE\Miscellaneous\Quality\Sample Reports\" + name, FileFormat:=wdFormatDocumentDefault, AddtoRecentFiles:=False
    
    'Zeroes out word/excel objects
    '---Set wDoc = Nothing
    '---Set wApp = Nothing
    '---Set wBook = Nothing
    
    '---MsgBox ("Report saved and objects zeroed out")
End Sub

Answer 1

First Occurrence by Rows (Find)

Using the Find method you can do the following:

Dim cel As Range
Dim tBound As Long
Set cRange = ActiveSheet.UsedRange
Set cel = cRange.Find( _
    What:=lNum, _
    After:=cRange.Cells(cRange.Cells.CountLarge), _
    LookIn:=xlFormulas, _
    LookAt:=xlWhole, _
    SearchOrder:=xlByRows)
If cel Is Nothing Then
    MsgBox "'" & lNum & "' not found in range '" & cRange.Address & "'."
    Exit Sub
End If
' No need for 'tHold'.
' If `cRange` starts in the first row, the following results are equal.
tBound = cel.Row ' worksheet row
'tBound = cel.Row - cRange.Row + 1 ' range row
MsgBox "First found row: " & CStr(tBound)