VBA 删除所有带有空格的行并删除行将包含字符串的单元格

Question

All, I have some VBA that deletes any row in which column C is blank. It also deletes and row in which Column A starts with 'Name' or 'Bar Name'. The problem is when I run these all together it only runs the first 2 steps. Furthermore, it doesn't actually turn off the filtering it's using and leaves the sheet filtered after it deletes the data.

Any idea how to get this to run as one step, this only seems to recognize the VBA for the first sheet?

Sub WB()
With ThisWorkbook.Worksheets("Geez")
Application.ScreenUpdating = False
Columns("C:C").SpecialCells(xlCellTypeBlanks).EntireRow.Delete
Application.ScreenUpdating = True
End With
End Sub

Sub WC()
With ThisWorkbook.Worksheets("Geez")
    .AutoFilterMode = False
    With Range("a1", Range("a" & Rows.Count).End(xlUp))
        .AutoFilter 1, "*Bar Name*"
        On Error Resume Next
        .Offset(1).SpecialCells(12).EntireRow.Delete
    End With
    .AutoFilterMode = False
End With
End Sub

Sub WE()
With ThisWorkbook.Worksheets("Class")
Application.ScreenUpdating = False
Columns("C:C").SpecialCells(xlCellTypeBlanks).EntireRow.Delete
Application.ScreenUpdating = True
End With
End Sub


Sub WF()
With ThisWorkbook.Worksheets("Class")
    .AutoFilterMode = False
    With Range("a1", Range("a" & Rows.Count).End(xlUp))
        .AutoFilter 1, "*Name*"
        On Error Resume Next
        .Offset(1).SpecialCells(12).EntireRow.Delete
    End With
    .AutoFilterMode = False
End With
End Sub

I try to run all and assign to a button using the below, but it only runs this for the first two steps. It also filters the first sheet, but doesn't actually remove the filter.

Sub Run1()
Call WB
Call WC
Call WE
Call WF
End Sub

Answer 1

Delete Empty and Filter

• If you do a procedure for empty cells and another for filtering on one value, you can easily use them in another procedure.
• Note all the occurrences of ws : they are showing where you have to put dots ( . ) instead if you plan to use the With statement : usually in front of Rows , Columns , Range , Cells ...
• When using On Error Resume Next (defer error handling (ignore errors)), you have to use a 'closing' On Error Goto 0 (turn off error handling).
• The 'slight inaccuracy' in defining the range is easily handled with Resize : you don't necessarily want to delete the row below the range.
• Using 12 instead of xlCellTypeVisible makes the code unnecessarily less readable.

The Code

Option Explicit

Sub doAll()
    
    Application.ScreenUpdating = False
    
    Dim ws As Worksheet
    
    Set ws = ThisWorkbook.Worksheets("Geez")
    doEmpty ws
    doFilter ws, "*Bar Name*"
    
    Set ws = ThisWorkbook.Worksheets("Class")
    doEmpty ws
    doFilter ws, "*Name*"
    
    Application.ScreenUpdating = True

End Sub

Sub doEmpty(ws As Worksheet)
    ws.AutoFilterMode = False
    ws.Columns("C:C").SpecialCells(xlCellTypeBlanks).EntireRow.Delete
End Sub

Sub doFilter(ws As Worksheet, ByVal FilterPattern As String)
    ws.AutoFilterMode = False
    With ws.Range("A1", ws.Range("A" & ws.Rows.Count).End(xlUp))
        .AutoFilter 1, FilterPattern
        On Error Resume Next
        .Resize(.Rows.Count - 1).Offset(1) _
            .SpecialCells(xlCellTypeVisible).EntireRow.Delete
        On Error GoTo 0
    End With
    ws.AutoFilterMode = False
End Sub