如何使用 Perl 提取某些行？

Question

I have string like this

Modified files: ['A', 'B']

File: /tpl/src/vlan/VlanInterfaceValidator.cpp

Newly generated warnings:
A has warnings
B has warning

Status: PASS

I want the value of "Newly generated warnings:" which should be

A has warnings
B has warning

I am new to perl and don't know how to use regex in Perl. Kindly help.

Answer 1

Here are two options:

• split the string into lines, and filter the lines array using grep
• use a regex on the multi-line string

my $str = "
Modified files: ['A', 'B']

File: /tpl/src/vlan/VlanInterfaceValidator.cpp

Newly generated warnings:
A has warnings
B has warning

Status: PASS";

my @lines = grep{ /\w+ has warning/ } split(/\n/, $str);

print "Option 1 using split and grep:\n";
print join("\n", @lines);

$str =~ s/^.*Newly generated warnings:\s*(.*?)\s+Status:.*$/$1/sm;
print "\n\nOption 2 using regex:\n";
print $str;

Output:

Option 1 using split and grep:
A has warnings
B has warning

Option 2 using regex:
A has warnings
B has warning

Explanation for option 1:

• split(/\n/, $str) - split the string into an array of strings
• grep{ /\w+ has warning/ } - filter using a grep regex to lines of interest
  • Note: This is short for the standard regex test $_ =~ /\w+ has warning/ . The $_ contains the string element, eg line.

Explanation for option 1:

• $str =~ s/search/replace/ - standard search and replace on a string
  • Note: Unlike in many other languages, strings are mutable in Perl
• s/^.*Newly generated warnings:\s*(.*?)\s+Status:.*$/$1/sm :
  • search:
    • ^.* - from beginning of string grab everything until:
    • Newly generated warnings:
    • \s+ - scan over whitespace
    • (.*?) - capture group 1 with non-greedy scan
    • \s+Status:.*$ - scan over whitespace, Status: , and everything else to end of string
  • replace:
    • $1 - use capture group 1
  • flags:
    • s - dot matches newlines
    • m - multiple lines, eg ^ is start of string, $ end of string

Answer 2

This sort of problem where you can read up to the line that has the section that you want and do nothing with those lines, then read lines until the start of the stuff you do want, keeping those lines:

# ignore all these lines
while( <DATA> ) {
    last if /Newly generated warnings/;
    }

# process all these lines
while( <DATA> ) {
    last if /\A\s*\z/;  # stop of the first blank line
    print;  # do whatever you need
    }

__END__
Modified files: ['A', 'B']

File: /tpl/src/vlan/VlanInterfaceValidator.cpp

Newly generated warnings:
A has warnings
B has warning

Status: PASS

That's reading from a filehandle. Handling a string is trivially easy because you can open a filehandle on a string so you can treat the string line-by-line:

my $string = <<'HERE';
Modified files: ['A', 'B']

File: /tpl/src/vlan/VlanInterfaceValidator.cpp

Newly generated warnings:
A has warnings
B has warning

Status: PASS
HERE

open my $fh, '<', \ $string;

while( <$fh> ) {
    last if /Newly generated warnings/;
    }

while( <$fh> ) {
    last if /\A\s*\z/;
    print;  # do whatever you need
    }