自动删除 Excel 中的特定行

Question

I'm trying to make it so that any row in my spreadsheet would automatically disappear when the value in one of the columns is changed from to "No" to "Yes" (drop-down list in that column, only two options to choose from: "Yes" and "No").

Example of what I'm trying to achieve:

• Cell L6 = "No"
• I'm changing the value in L6 from "No" to "Yes" using the drop-down list
• Row 6 is automatically deleted with no further steps

I'm under the impression this could be achieved with a macro (VBA code?) rather than using a formula, but my knowledge in macro is completely nonexistent - never used that before. I've tried using codes or bits of codes found online on similar questions, but nothing seems to be working. I've tried amending them to match my spreadsheet and the results I'm trying to obtain but it always ends in an error (and having never coded before, my attempts to fix them are unsuccessful since I don't understand them).

I'm willing to learn new things though, so any help is welcome!

Thanks in advance.

Answer 1

In your code for the worksheet, you want something like the following:

Private Sub Worksheet_Change(ByVal Target As Range)

    Dim Cell As Range
    'Make a list to store the rows to be deleted
    ReDim RowsToDelete(0) As Integer
    'Dummy item in the list prevents errors elsewhere in the code
    RowsToDelete(0) = 0

    'Check if any of the updated cells are in column L
    If Not Intersect(Target, Me.Range("L:L")) Is Nothing Then
        For Each Cell In Intersect(Target, Me.Range("L:L"))
           'If they are, for each such cell, see if the new value is "Yes"
            If Cell.Value = "Yes" Then
                'If it is, make our list one element longer
                ReDim Preserve RowsToDelete(UBound(RowsToDelete) + 1)
                'And add the row number as the last item
                RowsToDelete(UBound(RowsToDelete)) = Cell.Row
            End If
        Next Cell
    End If

    Dim intRow as Integer

    'Check if the list contains any row numbers for deletion
    If UBound(RowsToDelete) > 0 Then
        'Step through the rows from the last to the first
        'This prevents row numbers of rows still to be deleted changing
        For intRow = UBound(RowsToDelete) To 1 Step -1 'Loop excludes the 0th item as that's our dummy item
            Application.EnableEvents = False
            Me.Rows(RowsToDelete(intRow)).Delete Shift:=xlUp
            Application.EnableEvents = True
        Next intRow
    End If

End Sub

The Application.EnableEvents parts turn off (and back on) the firing of events. Without that, you'll find that each row deletion causes a further Worksheet Change event to be fired which creates looping weirdness.

I've tweaked the code to make it more robust when updating multiple rows at the same time. Probably the same thing can be done more efficiently in other ways.

Answer 2

Given that you're changing the value of the cells in Col L by using a dropdown, you could probably get away with relatively simple code - you just need to know where to place it. See Here for an explanation as to where to place the suggested code.

Private Sub Worksheet_Change(ByVal Target As Range)
If Not Intersect(Range("L:L"), Target) Is Nothing Then
    If Target.Text = "Yes" Then
        Target.EntireRow.Delete
    End If
End If
End Sub

Note that @Steve Lovell's answer is better if there's a chance of you changing multiple cells at the same time.