ORA-01422: 精确提取返回的行数多于请求的行数。 我可以使用此查询返回表中的所有行吗？

Question

select idstatus, paymonths 
  into status, monthly_payment_plan
from dd_pledge
where iddonor = donor_id;

I'm trying to retrieve all the rows returned from this query. It's working fine when I have only one row but if there is more than one row I get this error:

ORA-01422: exact fetch returns more than the requested number of rows.

Some of the answers I checked on the internet said use aggregate function and then group by clause, but I want to display all the returned values in a table.

Thank you.

Answer 1

With SELECT... INTO you can return a collection as single row.

Try the following reproducible example:

create or replace type onerow as object (name varchar2 (16), value varchar2 (96));
/
create or replace type rowtab as table of onerow;
/
create table tab (name, value) as
    select 'name'||rownum, 'value'||rownum
    from dual connect by level<=3
/
var rc refcursor
declare
    tab rowtab;
begin
    select cast (multiset (
        select name, value 
        from tab) as rowtab) into tab 
    from dual;
    open :rc for select * from table (tab);  
end;
/
print rc

Outcome:

NAME             VALUE           
---------------- ----------------
name1            value1          
name2            value2          
name3            value3          

Answer 2

You'll need something different than scalar variables. For example:

SQL> create or replace type t_row as object (ename varchar2(10), job varchar2(10));
  2  /

Type created.

SQL> create or replace type t_tab as table of t_row;
  2  /

Type created.

SQL> set serveroutput on
SQL> declare
  2    l_tab t_tab;
  3  begin
  4    select t_row(ename, job)
  5      bulk collect into l_tab
  6      from emp
  7      where deptno = 20;
  8
  9    for i in l_tab.first .. l_tab.last loop
 10      dbms_output.put_line(l_tab(i).ename ||' '|| l_tab(i).job);
 11    end loop;
 12  end;
 13  /
JONES MANAGER
SCOTT ANALYST
FORD ANALYST
SMITH CLERK
ADAMS CLERK

PL/SQL procedure successfully completed.

SQL>

Answer 3

If you are using SELECT... INTO... then you can only return a single row.

If you want multiple rows then you would need to SELECT... BULK COLLECT INTO... and put the values into collection variables. Or else, you could change to using a cursor .

For example:

DECLARE
  TYPE t_statuses              IS TABLE OF DD_PLEDGE.STATUS%TYPE;
  TYPE t_monthly_payment_plans IS TABLE OF DD_PLEDGE.MONTHLY_PAYMENT_PLAN%TYPE;
  
  p_statuses              t_statuses;
  p_monthly_payment_plans t_monthly_payment_plans;
  p_donor_id              DD_PLEDGE.IDDONOR%TYPE := 2;
BEGIN
  SELECT status, monthly_payment_plan
  BULK COLLECT INTO p_statuses, p_monthly_payment_plans
  FROM   dd_pledge
  WHERE  iddonor = p_donor_id;

  FOR i IN 1 .. p_statuses.COUNT LOOP
    DBMS_OUTPUT.PUT_LINE( p_statuses(i) || ', ' || p_monthly_payment_plans(i) );
  END LOOP;
END;
/

or

DECLARE
  TYPE t_pledges IS TABLE OF DD_PLEDGE%ROWTYPE;
  
  p_pledges   t_pledges;
  p_donor_id  DD_PLEDGE.IDDONOR%TYPE := 2;
BEGIN
  SELECT *
  BULK COLLECT INTO p_pledges 
  FROM   dd_pledge
  WHERE  iddonor = p_donor_id;

  FOR i IN 1 .. p_pledges.COUNT LOOP
    DBMS_OUTPUT.PUT_LINE( p_pledges(i).status || ', ' || p_pledges(i).monthly_payment_plan );
  END LOOP;
END;
/

With the sample data:

CREATE TABLE DD_PLEDGE (
  IDDONOR              NUMBER(4),
  PLEDGEAMT            NUMBER(8,2),
  STATUS               CHAR(1),
  MONTHLY_PAYMENT_PLAN VARCHAR2(20)
);

INSERT INTO dd_pledge ( iddonor, pledgeamt, status, monthly_payment_plan )
SELECT 1, 251.00, 'A', 'YES' FROM DUAL UNION ALL
SELECT 2, 250.01, 'B', 'NO'  FROM DUAL;

Both output:

 B, NO

db<>fiddle here