在关系 NEO4j 中添加属性

Question

I am trying to add up properties in the relationship along a path. This is my first week with NEO4j and I am now stuck. If anyone can advise. Thank you

match (dbn:City {name: 'Durban'})
match (unb:City {name: 'Pinetown'})
match path = shortestpath((dbn)-[dist:DISTANCE_TO*]->(unb))
return path, sum(dist.distance)

This path has a total of 4 nodes each with a different distance total of 19kms.

it gives an error of Type Mismatch expected Map but got list

Here is the code I did to generate the Graph

        merge  (c:Country {name: $Country}) 
            merge  (r:Region {name: $Region})   
            merge  (c1:City {name: $cityfrom})
            merge  (c2:City {name: $cityto})
            merge  (r)-[:IS_IN] -> (c)
            merge  (c1)-[:DISTANCE_TO {distance:toInteger($distance)}] -> (c2
            merge  (c2)-[:DISTANCE_TO {distance:toInteger($distance)}] -> (c1)
            merge  (c1)-[:IS_IN] -> (r)
            merge  (c2)-[:IS_IN] -> (r)

Answer 1

toInteger is your friend.

            merge  (r:Region {name: $Region})   
            merge  (c1:City {name: $cityfrom})
            merge  (c2:City {name: $cityto})
            merge  (r)-[:IS_IN] -> (c)
            merge  (c1)-[:DISTANCE_TO {distance:toInteger($distance)}] -> (c2)
            merge  (c2)-[:DISTANCE_TO {distance:toInteger($distance)}] -> (c1)
            merge  (c1)-[:IS_IN] -> (r)
            merge  (c2)-[:IS_IN] -> (r)

Answer 2

Given a path variable, you can use relationships(path) to get the list of relationships for it.

You can't use sum() on the path or the list of relationships, since sum() is an aggregation function that applies over multiple rows, not a scaler function that applies to a list.

You have some options.

If you UNWIND the relationships list to rows, then you can use sum() :

match (dbn:City {name: 'Durban'})
match (unb:City {name: 'Pinetown'})
match path = shortestpath((dbn)-[dist:DISTANCE_TO*]->(unb))
UNWIND relationships(path) as rel
return path, sum(rel.distance) as sum

You can install APOC Procedures and use apoc.coll.sum() to sum the elements of the collection:

match (dbn:City {name: 'Durban'})
match (unb:City {name: 'Pinetown'})
match path = shortestpath((dbn)-[dist:DISTANCE_TO*]->(unb))
return path, apoc.coll.sum([rel IN relationships(path) | rel.distance]) as sum

You can use the reduce() function to sum the distances:

match (dbn:City {name: 'Durban'})
match (unb:City {name: 'Pinetown'})
match path = shortestpath((dbn)-[dist:DISTANCE_TO*]->(unb))
return path, reduce(sum=0, rel IN relationships(path) | sum + rel.distance) as sum