在 VBA 代码中可靠地识别 Word 文档中的位置

Question

In Word I am endlessly running the below with incrementing numbers to find parts of document that I need to modify with VBA:

MsgBox (ActiveDocument.Paragraphs(56).Range.Text)

Also for tables. This is very slow and awkward; is there a way on the document to identify VBA 'locations' at the cursor is at?

For example if I highlight a word it would tell me "this is paragraph x, sentance y, word z" etc?

Answer 1

To get the paragraph number based on the selection you have to use a little jiggery pokery with the range object

Function GetParagraphNumber(ByVal ipRange As Word.Range) As Long

    ' NB The ByVal is critical
    ipRange.Start = 0
    GetParagraphNumber =ipRange.Paragraphs.Count + 1

End Function

SImilar functions can be derived for Words and Characters.

Answer 2

For example, the following identifies where a selection of any length in the document body begins & ends, including, if applicable, table indices and cell addresses:

Sub Demo()
Dim RngStart As Range, RngEnd As Range, RngSel As Range
Dim RngTxtStart As Range, RngTxtEnd As Range
Dim StrOut As String, StrAddr As String
With Selection
  Set RngSel = .Range
  Do While .Characters.Last Like "[ " & Chr(160) & "]"
    .End = .End - 1
    If .Start = .End Then Exit Do
  Loop
  Do While .Characters.First.Previous Like "[ " & Chr(160) & "]"
    .Start = .Start - 1
    If .Start = .End Then Exit Do
  Loop
End With
With ActiveDocument
  Set RngStart = .Range(0, Selection.Start)
  Set RngEnd = .Range(0, Selection.End)
  Set RngTxtStart = .Range(Selection.Paragraphs.First.Range.Start, Selection.Start)
  Set RngTxtEnd = .Range(Selection.Paragraphs.Last.Range.Start, Selection.End)
  StrOut = "The Selection starts in paragraph " & RngStart.Paragraphs.Count & _
    " at word " & RngTxtStart.ComputeStatistics(wdStatisticWords)
  If RngTxtStart.Information(wdWithInTable) = True Then
    With Selection
      StrAddr = " and the Selected "
      If .Cells.Count = 1 Then
        StrAddr = StrAddr & "cell address is: "
      Else
        StrAddr = StrAddr & "cells span: "
      End If
      StrAddr = StrAddr & ColAddr(.Cells(1).ColumnIndex) & .Cells(1).RowIndex
      If .Cells.Count > 1 Then
        StrAddr = StrAddr & ":" & ColAddr(.Characters.Last.Cells(1).ColumnIndex) & _
          .Characters.Last.Cells(1).RowIndex
      End If
    End With
  End If
  StrOut = StrOut & vbCr & "The Selection also starts in table " & RngTxtEnd.Tables.Count & StrAddr
    
  StrOut = StrOut & vbCr & "The Selection ends in paragraph " & RngEnd.Paragraphs.Count & _
    " at word " & RngTxtEnd.ComputeStatistics(wdStatisticWords)
  If RngTxtEnd.Information(wdWithInTable) = True Then
    With Selection
      StrAddr = " and the Selected "
      If .Cells.Count = 1 Then
        StrAddr = StrAddr & "cell address is: "
      Else
        StrAddr = StrAddr & "cells span: "
      End If
      StrAddr = StrAddr & ColAddr(.Cells(1).ColumnIndex) & .Cells(1).RowIndex
      If .Cells.Count > 1 Then
        StrAddr = StrAddr & ":" & ColAddr(.Characters.Last.Cells(1).ColumnIndex) & _
          .Characters.Last.Cells(1).RowIndex
      End If
    End With
    StrOut = StrOut & vbCr & "The Selection also ends in table " & RngTxtEnd.Tables.Count & StrAddr
  End If
  RngSel.Select
  MsgBox StrOut
End With
End Sub

Function ColAddr(i As Long) As String
If i > 26 Then
  ColAddr = Chr(64 + Int(i / 26)) & Chr(64 + (i Mod 26))
Else
  ColAddr = Chr(64 + i)
End If
End Function

This isn't really possible for sentences, as VBA has no idea what a grammatical sentence is.