如何自动更新 excel 链接数据？

Question

I have a source excel file(source) linked to a folder of files(templates), and all the templates are eventually linked to the output file(output). So if there are number updated in the source file, I need to open the templates one by one and refresh each template, and then refresh the output file to reflect the updates in all the template files. I am wondering if there's a way to make this process more efficient?

Thanks!

Answer 1

I can't give a specific answer, but I can give you some tips that may hopefully allow you to create the program that you're looking for.

To open a workbook in VBA you want to use Application.Workbooks.Open . To use that method, you need to know the exact file name and location. If you have a lot of files, you may want to define directories instead of individual file paths. That would be done like so:

Dim Directory as Object

Set Directory = CreateObject("Scripting.FileSystemObject").getfolder(DirectoryPath)
'DirectoryPath is the folder location written like "C:\Users\Guy\Documents\My Received Files\"

You can then loop through the files in the folder like so:

Dim oFile As Variant

For Each oFile In Directory.Files
    'Example of how to open them
    If oFile.Name Like "*.xls?" Then Application.Workbooks.Open oFile.Path
Next oFile

When you do Application.Workbooks.Open you can also save that workbook as a reference so that you can update the data inside it. You would do it like so:

Dim wb As Workbook

Set wb = Application.Workbooks.Open(FilePath)
'FilePath is the specific location of the File

Once you have the workbook, you can reference whichever cells you want using references like.Sheets("Sheet1").Range("A1").

To put everything I've discussed above into one example:

Sub Open_and_Edit()

    Dim Directory As Object, oFile As Variant, wb As Workbook, DirectoryPath As String

    'For this example, I'll use my desktop as the Directory
    DirectoryPath = "C:\Users\Michel\Desktop\"

    Set Directory = CreateObject("Scripting.FileSystemObject").getfolder(DirectoryPath)

    For Each oFile In Directory.Files
        'Opening every excel file on my desktop
        If oFile.Name Like "*.xls?" Then
            Set wb = Application.Workbooks.Open(oFile.Path)
            
            'opening and closing a dozen workbooks can cause annoying screen jittering, my prefered fix:
            wb.Windows(1).Visible = False
            
            wb.Sheets(1).Range("A1") = "Hello World!"
            
            wb.Close savechanges:=True
        End If
    Next oFile

End Sub