使用 vba 将 A 列中每个唯一值的 B 列中的所有值相加

Question

For some reason I think I am making this harder than it should be, but I am trying to do exactly what the title says. That is, when a person's name appears in one column I want to start a running count/sum of the values in another column throughout a list. For example, in the screenshot provided I would have gathered the following names and sums/values:

• Mary, 5
• George, 9
• Nick, 5
• Vani, 1
• Wes, 7

I want to create a bar chart with each person and their total but at the moment it's showing each entry individually on the chart (for example George would have 5 separate entries on the bar chart with values 3,1,1,3,1). All the names are also within a single Named Range as well if that helps.

Lastly, I want to do all this through VBA. The code now just simply looks like this:

ActiveSheet.Shapes.AddChart.Select
ActiveChart.SetSourceData Source:=Range("'SettingsSummary'!$D$3:$D$72,'SettingsSummary'!$E$3:$E$72")
ActiveChart.ChartType = xlColumnStacked

Answer 1

Please, test the next code. It assumes that the Names are in column A:A and their values in B:B. It skips the keys "-" and add zero in case of value being "-":

Sub UniqueValsInChart()
  Dim shT As Worksheet, ch As Chart, lastRow As Long
  Dim arrY, arrX, i As Long, dict As Object
  
  Set shT = ActiveSheet 'use here the sheet you need
  lastRow = shT.Range("A" & shT.rows.count).End(xlUp).row
  arrX = shT.Range("A4:B" & lastRow).value         'put the range in a array
  Set dict = CreateObject("Scripting.Dictionary")    'needed for the next step
  
  On Error Resume Next
   shT.ChartObjects("MyChartXY").Delete             'in case of running again the sub...
  On Error GoTo 0
  
  For i = 1 To UBound(arrX)
    If arrX(i, 1) <> "-" Then
        If Not dict.Exists(arrX(i, 1)) Then
            dict(arrX(i, 1)) = arrX(i, 2)                    'create the unique keys
        Else
            'add the values for the same key if they are not "-":
            dict(arrX(i, 1)) = dict(arrX(i, 1)) + IIf(arrX(i, 2) = "-", 0, arrX(i, 2))
        End If
    End If
  Next i
  arrX = dict.Keys: arrY = dict.items                   'extract the necessary arrays
  
  Set ch = shT.ChartObjects.Add(left:=shT.Range("E4").left, _
            top:=shT.Range("E4").top, width:=250, height:=250).Chart
  With ch
    .Parent.name = "MyChartXY"
    .ChartType = xlBarClustered
    .HasTitle = True
    .ChartTitle.Text = "Unique values..."
    .SeriesCollection.NewSeries.Values = arrY   'feed it with the array elements
    .SeriesCollection(1).XValues = arrX           'feed it with the array elements
  End With
  MsgBox "Ready..."
End Sub

Please, send some feedback after testing it.

Answer 2

Sounds to me like you want a Pivot table, not a chart. A Pivot table with rows=Name and Value=Sum of