VBA 如何锁定除一列之外的整个工作表并在条件下解锁

Question

I'm trying to lock a sheet for modification with VBA.

My goal is to lock all the sheet except column A. And when a row is equal to "MODIFICATION" it will unlock the entire row.

So far i managed to code this, but it locked all my sheet and not the correct zone.

Private Sub ProtectCells()    
    LastRow = ActiveSheet.Range("B2").End(xlDown).Row

    For i = 1 To LastRow    
        If Cells(i, 1) = "Modification" Then
            Range("B1:F3663").Locked = False
        Else
            Range("B1:F3663").Locked = True
        End If
    Next i

    ActiveSheet.Protect "pass"
End Sub

Answer 1

1. Lock all cells in the sheet
2. Filter for Modification rows and unlock them
3. Unlock column A
4. Protect the worksheet

Looks like below:

Option Explicit

Private Sub ProtectCells()
    Dim ws As Worksheet
    Set ws = ActiveSheet
    
    ' lock all cells
    ws.Cells.Locked = True
    
    ' filter for Modification in column A
    With ws.UsedRange
        .AutoFilter Field:=1, Criteria1:="Modification"
        ' unlock all visible rows of the filter
        On Error Resume Next ' hide error message if no cells with Modification were found
        .SpecialCells(xlCellTypeVisible).EntireRow.Locked = False
        On Error Goto 0 ' re-enable error reporting
    End With
    
    Selection.AutoFilter 'remove filter
    
    ' re-lock row 1 if this is a header row (filter unlocked it)
    ws.Rows(1).Locked = True
    
    ' unlock column A
    ws.Columns("A").Locked = False
    
    ' protect
    ws.Protect "PASS"
End Sub

Note that this code can only run once and the second time it will error because then the sheet is protected. If you want to be able to run it more than once you need a ws.Unprotect "PASS" in the beginning.

---

Edit according comment

Use the following code in the desired worksheet. This event unlocks the row if you write Modification in column A and locks it if you remove it.

Option Explicit

Private Const SHEET_PASSWORD As String = "PASS"

Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.CountLarge > 1 Then Exit Sub
    
    Me.Unprotect SHEET_PASSWORD
    
    If Me.Cells(Target.Row, "A").Value = "Modification" Then
        Me.Rows(Target.Row).Locked = False
    Else
        'lock row except column A if not modification
        Me.Rows(Target.Row).Resize(ColumnSize:=Me.Columns.Count - 1).Offset(ColumnOffset:=1).Locked = True
    End If
    
    Me.Protect SHEET_PASSWORD
End Sub

To prepare the worksheet run the following code initially before using the event to lock everything except column A.

Public Sub InitialProtection()
    Dim ws As Worksheet
    Set ws = ActiveSheet
    
    Me.Unprotect SHEET_PASSWORD
    ws.Cells.Locked = True
    ws.Columns("A").Locked = False
    Me.Protect SHEET_PASSWORD
End Sub