AppleScript：如何删除文件然后在进度条上加1%？

Question

So I have this code:

set theImages to choose file with prompt "Please select some images to process:" of type {"public.image"} with multiple selections allowed

-- Update the initial progress information
set theImageCount to length of theImages
set progress total steps to theImageCount
set progress completed steps to 0
set progress description to "Processing..."
set progress additional description to "Preparing to process your images..."

repeat with a from 1 to length of theImages
    -- Update the progress detail
    set progress additional description to "Processing image " & a & "/" & theImageCount
    
    -- Increment the progress
    set progress completed steps to a
    
    -- Pause for demonstration purposes, so progress can be seen
    delay (random number from 0.01 to 0.7)
    
    repeat with b in theImages
        tell application "Finder"
            try
                delete b
            end try
        end tell
    end repeat
end repeat

-- Reset the progress information
set progress total steps to 0
set progress completed steps to 0
set progress description to ""
set progress additional description to ""

display notification "All images were processed succesfully!" with title "Image Processer" subtitle "Images processed succesfully!" sound name "Frog"

And it is supposed to delete a file then add 1% to the progress bar but instead it deletes them all first then the progress bar does it's thing. How do I fix this?

Answer 1

There are two fatal issues:

1. You are deleting all files inside the loop so at the end of the first iteration there is no file left to be processed.

2. Even if you deleted only one file per iteration you will run into an out-of-index error because you are processing the files in ascending order. Imagine you have two files, after deleting the first one there is no item at index 2 anymore.

The solution is to delete one file per iteration and to delete the files backwards.

set theImages to choose file with prompt "Please select some images to process:" of type {"public.image"} with multiple selections allowed

-- Update the initial progress information
set theImageCount to length of theImages
set progress total steps to theImageCount
set progress completed steps to 0
set progress description to "Processing..."
set progress additional description to "Preparing to process your images..."

set repeatCount to 1
repeat with a from theImageCount to 1 by -1 -- count backwards
    -- Update the progress detail
    set progress additional description to "Processing image " & repeatCount & "/" & theImageCount
    
    -- Increment the progress
    set progress completed steps to repeatCount
    
    -- Pause for demonstration purposes, so progress can be seen
    delay (random number from 0.01 to 0.7)
    tell application "Finder"
        delete item a of theImages
    end tell
    set repeatCount to repeatCount + 1
end repeat

-- Reset the progress information
set progress total steps to 0
set progress completed steps to 0
set progress description to ""
set progress additional description to ""

display notification "All images were processed succesfully!" with title "Image Processer" subtitle "Images processed succesfully!" sound name "Frog"

Side note: Strictly spoken you don't add 1%, you add (100/theImageCount)%