如果任一列中的一个或多个单元格为空白，则删除整行

Question

I am trying to iterate through rows and delete a row if there is a blank cell in the row, on a button click, regardless of what column it is in.

I have 151 rows and Columns A to L.

When I run the code all my rows disappear.

Sub Button3_Click()
Dim lRow As Long
Dim iCntr As Long
Dim col As Integer
col = 1
lRow = 151
For iCntr = lRow To 1 Step -1
    If Trim(Cells(iCntr, col)) = "" Then
        Rows(iCntr).Delete
    End If
    col = col + 1
Next
    
End Sub

Answer 1

You need to loop across a fixed set of columns too - at the moment you appear to be just examining just one one cell per row - the col = col + 1 means you examine a diagonal stripe of cells, different column on each row.

Anyway it's better to collect all deletion rows and delete at the end of the process, so that you're not altering the space you're examining.

Sub Button3_Click()
Dim irx As Long
Dim ARow As Range
Dim ACell As Range
Dim DelSet As Range

Set DelSet = Nothing
For irx = 1 To 151
    Set ARow = Range(Cells(irx, 1), Cells(irx, 12))
    For Each ACell In ARow
        If Trim(ACell.Value) = "" Then
            If DelSet Is Nothing Then
                Set DelSet = ACell.EntireRow
            Else
                Set DelSet = Union(DelSet, ACell.EntireRow)
            End If
            Exit For
        End If
    Next ACell
Next irx

If Not DelSet Is Nothing Then
    DelSet.Delete
End If

End Sub

To see what this is doing, without actually deleting anything, you could change the DelSet.Delete into DelSet.Select and it will show you what the allocated region for deletion is.

I recognize from your comment that this use of Range object variables might be new to you, but definitely worth learning.

Answer 2

Delete Rows Containing At Least One Blank Cell

• If any of the cells in a row of the 'given' range ( rg ) is blank ( empty , ="" , ' etc.), then the row range ( rrg ) will be combined (using Union ) into the Delete Range ( drg ). Finally, the entire rows of the Delete Range will be deleted.
• Your use of Trim may indicate that you also want to delete rows containing spaces. This is not covered by this solution (a cell is not blank if it contains a space).

A Quick Fix

Option Explicit

Sub Button3_Click()
    
    Const Cols As String = "A:L"
    Const First As Long = 1
    Const Last As Long = 151
        
    Dim rg As Range: Set rg = Columns(Cols).Rows(First & ":" & Last)
    
    Dim drg As Range
    Dim rrg As Range
    
    For Each rrg In rg.Rows
        If Application.CountBlank(rrg) > 0 Then
            If drg Is Nothing Then
                Set drg = rrg
            Else
                Set drg = Union(drg, rrg)
            End If
        End If
    Next rrg
    
    If Not drg Is Nothing Then
        drg.EntireRow.Delete
    End If
    
End Sub

Your Idea Fixed

Sub Button3_Click()
    
    Const fRow As Long = 1
    Const lRow As Long = 151
    Const fCol As Long = 1 ' ("A")
    Const lCol As Long = 12 ' ("L")
    
    Dim r As Long, c As Long
    
    For r = lRow To fRow Step -1
        For c = fCol To lCol
            If Trim(Cells(r, c).Value) = "" Then
                Rows(r).Delete
                Exit For ' found and deleted: don't loop the columns any more
            End If
        Next c
    Next r
    
End Sub

Answer 3

you need to select the row using the sintaxis: Eg Rows(nrow:nrow).select --> Rows(4:4).select

But you are counting in countdown, I guess you will need to count how many rows you have deleted. to select the right row.

Good luck

Sub Button3_Click()
    Dim lRow As Long
    Dim iCntr As Long
    Dim col As Integer
    col = 1
    lRow = 151
    For iCntr = lRow To 1 Step -1
        For col = 1 To 12 '12 is L
            If Trim(Cells(iCntr, col)) = "" Then
                Rows(iCntr & ":" & iCntr).Select
                Selection.Delete Shift:=xlUp
                Exit For ' if found 1 blank, get out afeter delete
                'After delet check wich cell you need to be stan on
            End If
        Next col
    Next
End Sub