带有 union all 的存储过程循环

Question

I need help to optimize the stored procedure shown here. It works, but when it runs it generates a select script for each database. I need the stored procedure to union all select statements.

Does anyone know how to make this work?

SET NOCOUNT ON;
SET TRANSACTION ISOLATION LEVEL READ UNCOMMITTED;

IF OBJECT_ID('tempdb.dbo.#database') IS NOT NULL
    DROP TABLE #database

CREATE TABLE #database
(
    id INT IDENTITY PRIMARY KEY, 
    name sysname
)

SET NOCOUNT ON

BEGIN

INSERT INTO #database(name) 
    SELECT name
    FROM master.sys.databases 
    WHERE name IN (SELECT [DATABASE] COLLATE Latin1_General_CI_AS  
                   FROM SETTINGS.DBO.SETTINGS
                   WHERE [KEY] = 'DB_NAME' AND SETTING = '1' )
    ORDER BY name
END

DECLARE @id INT, @cnt INT, @sql NVARCHAR(max), @currentDb sysname;

SELECT @id = 1, @cnt = MAX(id)
FROM #database

WHILE @id <= @cnt
BEGIN
    SELECT @currentDb = name
    FROM #database
    WHERE id = @id

    SET @sql =  'select * FROM ' + @currentDb + '.dbo.People'
    PRINT @sql

    EXEC (@sql);  
    
    PRINT '--------------------------------------------------------------------------'
    SET @id = @id + 1; 
END

DROP TABLE #database
END

Answer 1

Build your dynamic string inside your loop and only execute it once the loop has finished.

WHILE @id <= @cnt BEGIN
    SELECT @currentDb = [name]
    FROM #database
    WHERE id = @id;

    SET @sql = @sql + CASE WHEN LEN(@sql) > 0 THEN ' union all ' ELSE '' END
        + 'SELECT * FROM ' + QUOTENAME(@currentDb) + '.dbo.People';

    SET @id = @id + 1; 
END;
IF len(@sql) > 0 BEGIN
    print @sql
    exec (@sql); 
END;

Note use QUOTENAME to prevent SQL injection issues - even if just by accident.

Answer 2

I changed the code and copied and tried below link, and it works perfect. Thanks for your help.

How do you use a cursor to combine data in a Union All?

DECLARE @sql NVARCHAR(MAX) = N'';

SELECT @sql = @sql +
'UNION ALL SELECT column1 FROM ' + QUOTENAME(name) + '..tableA' + CHAR(10)
FROM sys.databases 
WHERE [name] NOT IN ('master', 'tempdb', 'model', 'msdb')

SELECT @sql = STUFF(@sql, 1, 10, '')

PRINT @sql
EXEC (@sql)