如何编写 SQL 查询来计算一个项目在一周内出现的次数？

Question

I'm trying to write a PROC SQL query to count how many times a week a particular object is bought. The issue is, I'm not sure how to code for the 7 day part. I was originally thinking of writing code that looks like this:

PROC SQL;
SELECT COUNT(DATE_FILE)
FROM DATA 
WHERE DATE BETWEEN (03-07-2021) and (03-14-2021)
GROUP BY OBJECT 
QUIT;

The thing is, I can't go in and manually look at all of the dates in a week - I need to have the code automatically and accurately account for a week. How should I write this?

Answer 1

I am not sure if your data looks like this, but you can use week function and also find the beg and end dates to represent a week. I used sample code:

  data test;
  input items $4. date date9.;
  week_no=week(date);
  format date date9.;
  datalines;
  obj1 1-Jan-21
  obj2 2-Jan-21
  obj1 3-Jan-21
  obj3 4-Jan-21
  obj1 5-Jan-21
  obj2 6-Jan-21
  obj3 7-Jan-21
  obj4 7-Jan-21
  obj1 8-Jan-21
  obj2 9-Jan-21
  obj3 10-Jan-21
  obj1 11-Jan-21
  obj2 12-Jan-21
  obj3 13-Jan-21
  obj1 14-Jan-21
  obj1 15-Jan-21
  obj2 16-Jan-21
  obj3 17-Jan-21
  obj4 18-Jan-21
  obj2 19-Jan-21
  obj3 20-Jan-21
  obj1 21-Jan-21
  obj2 22-Jan-21
  obj1 23-Jan-21
  obj2 24-Jan-21
  obj4 25-Jan-21
  obj4 26-Jan-21
  obj1 27-Jan-21
  obj2 28-Jan-21
  obj4 29-Jan-21
  obj1 30-Jan-21
  obj1 31-Jan-21
  obj4 1-Feb-21
  obj2 2-Feb-21
  obj2 3-Feb-21
  obj3 3-Feb-21
  ;
  run;
  
  data find_week last_of_each_week(keep=week_no beg_end);
  length beg_end $50.;
   set test;
    by week_no;
  
    retain beg_end '';
    if first.week_no then beg_end=put(date, date9.);
    else if last.week_no then beg_end=catx("-",beg_end,put(date, date9.));
    
    output find_week;
    if last.week_no then output last_of_each_week;
  run;
  
  proc sql;
  create table week_data
  as
  select date, items, a.week_no, b.beg_end
  from find_week a
  inner join last_of_each_week b
  on a.week_no=b.week_no;
  quit;
  
  proc sql;
  create table count_obj
  as
  select beg_end, week_no, items, count(items)
  from week_data
  group by beg_end, week_no, items
  order by week_no, items;
  quit;

  proc print data=count_obj; run;

You can see final output by week number, week dates and count of objects. Output will look like this:

Answer 2

It might be as simple as the week function :

PROC SQL;
  SELECT week(date,'U') as weeknum, COUNT(DATE_FILE) as per_week
    FROM DATA 
    GROUP BY week(date,'U');  *'u' argument means to start on Sunday;
QUIT;

This doesn't work across years though, so if you have more data, either include also the year function or use intnx .