SAS Enterprise Guide proc sql - 使用 when 语句包含在内

Question

I am trying to organize members by years when they were enrolled (in order to calculate retention) but I'm running into an issue. Namely, the code I'm using only assigns one year to each member, whereas I want to know all the years when they were enrolled. I need the program to assign more than one year where appropriate (and most members are there for multiple years).

My code is as follows:

proc sql;
create table tmp7day.ash_yearly_totals as
select prsn_uniq_id, 
(case 
when min_of_yyyymm < 201501 and max_of_yyyymm > 201312 then 2014
when min_of_yyyymm < 201601 and max_of_yyyymm > 201412 then 2015
when min_of_yyyymm < 201701 and max_of_yyyymm > 201512 then 2016
when min_of_yyyymm < 201801 and max_of_yyyymm > 201612 then 2017
when min_of_yyyymm < 201901 and max_of_yyyymm > 201712 then 2018
when min_of_yyyymm < 202001 and max_of_yyyymm > 201812 then 2019
when min_of_yyyymm < 202101 and max_of_yyyymm > 201912 then 2020
when min_of_yyyymm < 202105 and max_of_yyyymm > 202012 then 202104
else 0
end) as Year 
from tmp7day.retention_with_ash
where ash_ind = 1
/*group by year;*/
order by year asc;
quit;

Any suggestions would be appreciated. Please let me know if my question didn't make sense.

Answer 1

There are two solutions to this,

1. Create multiple year variables like year_2014, year_2015,.., year_2021.. etc,. and keep 'Y' in each variable based on different conditions. (Horizontal data)

2. Create multiple records per member using output statement. each record will have respective year in Year variable. (Vertical data)

Sample Code:

data class;
   set sashelp.class(firstobs=1 obs=6);
   if _n_=1 then do;
      min_of_yyyymm=201503;
      max_of_yyyymm=201602;
   end;
   else if _n_=2 then do;
      min_of_yyyymm=201403;
      max_of_yyyymm=202004;
   end;
   else if _n_=3 then do;
      min_of_yyyymm=201603;
      max_of_yyyymm=201804;
   end;
   else if _n_=4 then do;
      min_of_yyyymm=201503;
      max_of_yyyymm=201904;
   end;
   else if _n_=5 then do;
      min_of_yyyymm=201603;
      max_of_yyyymm=201704;
   end;
   else if _n_=6 then do;
      min_of_yyyymm=201803;
      max_of_yyyymm=202104;
   end;
run;

/* create seperate record for each year per memner/name/id */
data class1;
   set class;
   if min_of_yyyymm < 201501 and max_of_yyyymm > 201312 then do; year= 2014;output; end;
   if min_of_yyyymm < 201601 and max_of_yyyymm > 201412 then do; year= 2015;output; end;
   if min_of_yyyymm < 201701 and max_of_yyyymm > 201512 then do; year= 2016;output; end;
   if min_of_yyyymm < 201801 and max_of_yyyymm > 201612 then do; year= 2017;output; end;
   if min_of_yyyymm < 201901 and max_of_yyyymm > 201712 then do; year= 2018;output; end;
   if min_of_yyyymm < 202001 and max_of_yyyymm > 201812 then do; year= 2019;output; end;
   if min_of_yyyymm < 202101 and max_of_yyyymm > 201912 then do; year= 2020;output; end;
   if min_of_yyyymm < 202105 and max_of_yyyymm > 202012 then do; year= 202104;output; end;
run;

/* or (more dynamic way, works for any range of years) */

data class2 (drop=i);
   set class;
   do i=(min_of_yyyymm-mod(min_of_yyyymm,100))/100 to (max_of_yyyymm-mod(max_of_yyyymm,100))/100;
      year=i;output;
   end;
run;

proc sort data=class2;
   by year name;
run;

proc report data=class2;
   column year name;
   define year/order group;
   define name/order;
run;

enter image description here